[harmony] Bug 1983391: Add a donation banner to the home page

Bugzilla/Config/Donation.pm

@@ -0,0 +1,36 @@
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+#
+# This Source Code Form is "Incompatible With Secondary Licenses", as
+# defined by the Mozilla Public License, v. 2.0.
+
+package Bugzilla::Config::Donation;
+
+use 5.14.0;
+use strict;
+use warnings;
+
+use Bugzilla::Config::Common;
+
+our $sortkey = 175;
+
+use constant get_param_list => (
+  {
+    name    => 'donation_banner_visibility',
+    type    => 's',
+    choices => ['admins_only', 'end_users', 'disabled'],
+    default => 'admins_only',
+    checker => \&check_multi,
+  },
+);
+
+1;
+
+__END__
+
+=head1 NAME
+
+Bugzilla::Config::Donation - Donation banner settings
+
+=cut

Bugzilla/Donation.pm

@@ -0,0 +1,137 @@
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+#
+# This Source Code Form is "Incompatible With Secondary Licenses", as
+# defined by the Mozilla Public License, v. 2.0.
+
+package Bugzilla::Donation;
+
+use 5.14.0;
+use strict;
+use warnings;
+
+use Bugzilla::Constants;
+use Bugzilla::Error;
+use Bugzilla::Token qw(issue_hash_token);
+use Bugzilla::Util qw(validate_date);
+
+use DateTime;
+
+use constant BANNER_URL => 'https://bugzilla.org/donate';
+use constant BANNER_MESSAGES => (
+  'Help us make Bugzilla better more often.',
+  'A small donation helps keep Bugzilla moving forward.',
+  'Support the people who keep Bugzilla running.',
+  'Even a little funding helps Bugzilla improve more quickly.',
+  'If Bugzilla helps your team, consider helping Bugzilla too.',
+);
+
+sub get_banner {
+  my $user = Bugzilla->user;
+  return undef if !$user->id;
+
+  my $visibility = Bugzilla->params->{'donation_banner_visibility'} || 'admins_only';
+  return undef if $visibility eq 'disabled';
+  return undef if $visibility eq 'admins_only' && !$user->in_group('admin');
+
+  my $settings = $user->settings;
+  my $pref = $settings->{'donate_banner_pref'}->{'value'};
+  my $last_version = $settings->{'donate_banner_last_version'}->{'value'} || '0.0';
+  my $next_date = $settings->{'donate_banner_reminder_date'}->{'value'} || '1970-01-01';
+  my $current_version = BUGZILLA_VERSION;
+
+  my $show;
+  my $show_thanks = 0;
+  if ($pref eq 'next_upgrade') {
+    $show = ($last_version ne $current_version);
+    $show_thanks = $show
+      && $user->in_group('admin')
+      && $last_version ne '0'
+      && $last_version ne '0.0';
+  }
+  elsif ($pref eq 'specific_date') {
+    my $today = DateTime->now(time_zone => Bugzilla->local_timezone)->ymd;
+    $show = ($next_date le $today);
+  }
+  else {
+    $show = 0;
+  }
+
+  return undef if !$show;
+
+  my @messages = BANNER_MESSAGES;
+  my $message = $messages[int(rand(@messages))];
+
+  my $data = {
+    url           => BANNER_URL,
+    message       => $message,
+    show_thanks   => $show_thanks,
+    visibility    => $visibility,
+    settings_link => 'editparams.cgi?section=donation#donation_banner_visibility_desc',
+    token         => issue_hash_token(['donation_banner']),
+    today         => DateTime->now(time_zone => Bugzilla->local_timezone)->ymd,
+  };
+
+  if ($visibility eq 'admins_only') {
+    $data->{'visibility_note'}
+      = 'This message is only shown to logged-in users with admin privs.';
+  }
+  elsif ($user->in_group('admin')) {
+    $data->{'visibility_note'}
+      = 'This message is visible to all logged-in users.';
+  }
+
+  return $data;
+}
+
+sub set_banner_preference {
+  my ($action, $date) = @_;
+  my $user = Bugzilla->user;
+  my $settings = $user->settings;
+
+  my $pref_setting = $settings->{'donate_banner_pref'};
+  my $date_setting = $settings->{'donate_banner_reminder_date'};
+  my $version_setting = $settings->{'donate_banner_last_version'};
+  my $current_version = BUGZILLA_VERSION;
+
+  if ($action eq 'next_upgrade') {
+    $pref_setting->set('next_upgrade');
+    $version_setting->set($current_version);
+    return 'index.cgi';
+  }
+  if ($action eq 'week' || $action eq 'month') {
+    my $days = $action eq 'week' ? 7 : 30;
+    my $dt = DateTime->now(time_zone => Bugzilla->local_timezone);
+    $dt->add(days => $days);
+    $pref_setting->set('specific_date');
+    $date_setting->set($dt->ymd);
+    $version_setting->set($current_version);
+    return 'index.cgi';
+  }
+  if ($action eq 'never') {
+    $pref_setting->set('never');
+    $version_setting->set($current_version);
+    return 'index.cgi';
+  }
+  if ($action eq 'date') {
+    validate_date($date)
+      || ThrowUserError('illegal_date', {date => $date, format => 'YYYY-MM-DD'});
+    $pref_setting->set('specific_date');
+    $date_setting->set($date);
+    $version_setting->set($current_version);
+    return 'index.cgi';
+  }
+
+  return 'index.cgi';
+}
+
+1;
+
+__END__
+
+=head1 NAME
+
+Bugzilla::Donation - Donation banner helpers
+
+=cut

Bugzilla/Install.pm

@@ -58,6 +58,24 @@ sub SETTINGS {
       category => 'Searching'
     },
 
+    # 2026-07-01 bugzilla@mozilla.org -- Bug 1983391
+    {
+      name     => 'donate_banner_pref',
+      options  => ['next_upgrade', 'specific_date', 'never'],
+      default  => 'next_upgrade',
+      category => 'Bugzilla.org',
+    },
+    {
+      name     => 'donate_banner_last_version',
+      default  => '0.0',
+      category => 'Bugzilla.org',
+    },
+    {
+      name     => 'donate_banner_reminder_date',
+      default  => '1970-01-01',
+      category => 'Bugzilla.org',
+    },
+
     # 2005-03-10 travis@sedsystems.ca -- Bug 199048
     {
       name => 'comment_sort_order',

Bugzilla/Install/DB.pm

@@ -3070,7 +3070,13 @@ sub _rederive_regex_groups {
 
   $sth->execute(GRANT_REGEXP);
   while (my ($uid, $login, $gid, $rexp, $present) = $sth->fetchrow_array()) {
-    if ($login =~ m/$rexp/i) {
+    my $matches = eval { $login =~ m/$rexp/i ? 1 : 0 };
+    if ($@) {
+      print "Skipping invalid group regexp for group $gid: $rexp\n";
+      next;
+    }
+
+    if ($matches) {
       $sth_add->execute($uid, $gid) unless $present;
     }
     else {

index.cgi

@@ -15,6 +15,8 @@ use lib qw(. lib local/lib/perl5);
 use Bugzilla;
 use Bugzilla::Constants;
 use Bugzilla::Error;
+use Bugzilla::Token;
+use Bugzilla::Donation;
 use Bugzilla::Update;
 use Digest::MD5 qw(md5_hex);
 use List::MoreUtils qw(any);
@@ -44,6 +46,20 @@ if ($cgi->param('logout')) {
   $cgi->delete('logout');
 }
 
+my $donate_action = $cgi->param('donate_action');
+if ($donate_action) {
+  Bugzilla->login(LOGIN_REQUIRED) unless Bugzilla->user->id;
+
+  my $token = $cgi->param('token');
+  check_hash_token($token, ['donation_banner']);
+
+  my $redirect = Bugzilla::Donation::set_banner_preference($donate_action,
+    scalar $cgi->param('donate_banner_reminder_date'));
+
+  print $cgi->redirect(-uri => $redirect);
+  exit;
+}
+
 # our weak etag is based on the Bugzilla version parameter (BMO customization) and the announcehtml
 # if either change, the cache will be considered invalid.
 my @etag_parts = (
@@ -69,7 +85,7 @@ if (
 else {
   my $template = Bugzilla->template;
   $C->content_security_policy(
-    script_src => ['self', 'https://www.google-analytics.com']);
+    script_src => ['self', 'nonce', 'https://www.google-analytics.com']);
 
   # Return the appropriate HTTP response headers.
   print $cgi->header(
@@ -90,6 +106,8 @@ else {
     $vars->{'release'} = Bugzilla::Update::get_notifications();
   }
 
+  $vars->{'donation'} = Bugzilla::Donation::get_banner();
+
   # Generate and return the UI (HTML page) from the appropriate template.
   $template->process("index.html.tmpl", $vars)
     or ThrowTemplateError($template->error());