[Artifact1620] サテライトドロップの作成

Asset/data/asset/functions/artifact/1620.satelite_drop/attack/.mcfunction

@@ -0,0 +1,33 @@
+#> asset:artifact/1620.satelite_drop/attack/attack
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/**
+
+# ランダムなObject 1192からO1192.Idleを外す
+    execute as @e[type=marker,tag=O1192.Idle,distance=..3] if score @s O1192.UserID = @p[tag=this] UserID run tag @s add O1192.Launchable
+    #なんらかの理由でObjectが近くに存在しない場合、LaunchInstantlyをtrueにした状態のObjectを新しく召喚
+    execute unless entity @e[type=marker,tag=O1192.Launchable,distance=..3] run function asset:artifact/1620.satelite_drop/attack/launch_new
+
+    execute anchored eyes positioned ^ ^-0.1 ^0.5 as @e[type=marker,tag=O1192.Launchable,distance=..3,sort=arbitrary,limit=1] if score @s O1192.UserID = @p[tag=this] UserID run function asset:artifact/1620.satelite_drop/attack/launch
+    tag @e[type=marker,tag=O1192.Launchable,distance=..3] remove O1192.Launchable
+
+# Effect396のスタックを1減らす
+    data modify storage api: Argument.ID set value 396
+    function api:entity/mob/effect/get/from_id
+    data modify storage asset:context this.Return set from storage api: Return.Effect
+
+    data modify storage api: Argument.ID set value 396
+    execute store result storage api: Argument.Stack int 0.9999999999 run data get storage asset:context this.Return.Stack
+    data modify storage api: Argument.Duration set from storage asset:context this.Return.Duration
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# クールダウン用Effect397を付与
+    data modify storage api: Argument.ID set value 397
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# 演出
+    playsound entity.drowned.death player @a ~ ~ ~ 1 1.7
+    playsound entity.zombie.converted_to_drowned player @a ~ ~ ~ 1 1.4

Asset/data/asset/functions/artifact/1620.satelite_drop/attack/launch.mcfunction

@@ -0,0 +1,11 @@
+#> asset:artifact/1620.satelite_drop/attack/launch
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/attack/
+
+# O1192.Idleを外す
+    tag @s remove O1192.Idle
+
+# 位置を調整
+    tp @s ^ ^ ^ ~ ~

Asset/data/asset/functions/artifact/1620.satelite_drop/attack/launch_new.mcfunction

@@ -0,0 +1,22 @@
+#> asset:artifact/1620.satelite_drop/attack/launch_new
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/attack/
+
+    data modify storage api: Argument.FieldOverride.LaunchInstantly set value true
+    data modify storage api: Argument.FieldOverride.Count set value 1
+    # 攻撃情報
+        data modify storage api: Argument.FieldOverride.Damage set value 150
+        data modify storage api: Argument.FieldOverride.AttackType set value "Magic"
+        data modify storage api: Argument.FieldOverride.ElementType set value "Water"
+
+    # 発射体のField
+        data modify storage api: Argument.FieldOverride.Speed set value 3
+        data modify storage api: Argument.FieldOverride.Range set value 30
+
+    execute store result storage api: Argument.FieldOverride.UserID int 1 run scoreboard players get @s UserID
+    data modify storage api: Argument.ID set value 1192
+    function api:object/summon
+
+    execute anchored eyes positioned ^ ^-0.1 ^0.5 as @e[type=marker,scores={ObjectID=1192},distance=..3] if score @s O1192.UserID = @p[tag=this] UserID rotated as @p[tag=this] run tp @s ^ ^ ^ ~ ~

Asset/data/asset/functions/artifact/1620.satelite_drop/dis_equip/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1620.satelite_drop/dis_equip/1.trigger
+#
+#
+#
+# @within tag/function asset:artifact/dis_equip
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1620} run function asset:artifact/1620.satelite_drop/dis_equip/2.main

Asset/data/asset/functions/artifact/1620.satelite_drop/dis_equip/2.main.mcfunction

@@ -0,0 +1,10 @@
+#> asset:artifact/1620.satelite_drop/dis_equip/2.main
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/dis_equip/1.trigger
+
+# Effect395を削除
+    data modify storage api: Argument.ID set value 395
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset

Asset/data/asset/functions/artifact/1620.satelite_drop/give/1.trigger.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1620.satelite_drop/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1620} run function asset:artifact/1620.satelite_drop/give/2.give

Asset/data/asset/functions/artifact/1620.satelite_drop/give/2.give.mcfunction

@@ -0,0 +1,68 @@
+#> asset:artifact/1620.satelite_drop/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1620.satelite_drop/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1620
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:ender_eye"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text": "サテライトドロップ", "color": "#6abcf6"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text": "クールダウンと消費MPを無視して発射ができる弾を召喚する(最大3個)。"}', '{"translate": "弾はチャージ時間1.5秒につき数が一つ増え、%sの間残る。", "with":[{"text": "召喚した数x30秒", "color": "aqua"}]}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "releaseUsingItem"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value "150x1-3"
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Magic]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Water]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "never"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value 15
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 40
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    data modify storage asset:artifact LocalCooldown set value 200
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact TypeCooldown.Type set value "longRange"
+    data modify storage asset:artifact TypeCooldown.Duration set value 15
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ['Flora', 'Wi-ki', 'Rumor']
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give

Asset/data/asset/functions/artifact/1620.satelite_drop/register.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1620.satelite_drop/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[3] append value [1620]
+data modify storage asset:artifact RarityRegistryWithColor.Red[3] append value [1620]

Asset/data/asset/functions/artifact/1620.satelite_drop/release_using_item/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1620.satelite_drop/release_using_item/1.trigger
+#
+#
+#
+# @within tag/function asset:artifact/using_item/release/
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1620} run function asset:artifact/1620.satelite_drop/release_using_item/2.check_condition

Asset/data/asset/functions/artifact/1620.satelite_drop/release_using_item/2.check_condition.mcfunction

@@ -0,0 +1,15 @@
+#> asset:artifact/1620.satelite_drop/release_using_item/2.main
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/release_using_item/1.trigger
+
+# Effect396があるならキャンセル
+    data modify storage api: Argument.ID set value 396
+    function api:entity/mob/effect/get/from_id
+    execute if data storage api: Return.Effect run return fail
+
+# Effect395がある(=チャージ中)ならチャージ終了処理
+    data modify storage api: Argument.ID set value 395
+    function api:entity/mob/effect/get/from_id
+    execute if data storage api: Return.Effect run function asset:artifact/1620.satelite_drop/release_using_item/3.main

Asset/data/asset/functions/artifact/1620.satelite_drop/release_using_item/3.main.mcfunction

@@ -0,0 +1,39 @@
+#> asset:artifact/1620.satelite_drop/release_using_item/3.main
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/release_using_item/2.check_condition
+
+#> private
+# @private
+    #declare score_holder $A1620.Stack
+
+# Effect396を付与
+    data modify storage api: Argument.ID set value 395
+    function api:entity/mob/effect/get/from_id
+    data modify storage api: Argument.ID set value 396
+
+    # チャージ段階に応じて効果時間とスタックを設定
+        execute store result score $A1620.Stack Temporary run data get storage api: Return.Effect.Stack
+        execute store result storage api: Argument.Stack int 1 run scoreboard players get $A1620.Stack Temporary
+        execute store result storage api: Argument.Duration int 600 run scoreboard players get $A1620.Stack Temporary
+
+    # 攻撃情報
+        data modify storage api: Argument.FieldOverride.Damage set value 150
+        data modify storage api: Argument.FieldOverride.AttackType set value "Magic"
+        data modify storage api: Argument.FieldOverride.ElementType set value "Water"
+
+    # 発射体のField
+        data modify storage api: Argument.FieldOverride.Speed set value 3
+        data modify storage api: Argument.FieldOverride.Range set value 30
+
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# Effect395を削除
+    data modify storage api: Argument.ID set value 395
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset
+
+# リセット
+    scoreboard players reset $A1620.Stack

Asset/data/asset/functions/artifact/1620.satelite_drop/using_item/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1620.satelite_drop/using_item/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1620} run function asset:artifact/1620.satelite_drop/using_item/2.check_condition

Asset/data/asset/functions/artifact/1620.satelite_drop/using_item/2.check_condition.mcfunction

@@ -0,0 +1,26 @@
+#> asset:artifact/1620.satelite_drop/using_item/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1620.satelite_drop/using_item/1.trigger
+
+# クールダウン中(Effect397保持中)ならキャンセル
+    data modify storage api: Argument.ID set value 397
+    function api:entity/mob/effect/get/from_id
+    execute if data storage api: Return.Effect run return fail
+
+# チャージ中(Effect395保持中)ならチャージ続行
+    data modify storage api: Argument.ID set value 395
+    function api:entity/mob/effect/get/from_id
+    execute if data storage api: Return.Effect run return run function asset:artifact/1620.satelite_drop/using_item/charge/check
+
+# Effect396があるなら攻撃
+    data modify storage api: Argument.ID set value 396
+    function api:entity/mob/effect/get/from_id
+    execute if data storage api: Return.Effect run return run function asset:artifact/1620.satelite_drop/attack/
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1620.satelite_drop/using_item/3.main

Asset/data/asset/functions/artifact/1620.satelite_drop/using_item/3.main.mcfunction

@@ -0,0 +1,17 @@
+#> asset:artifact/1620.satelite_drop/using_item/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1620.satelite_drop/using_item/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# 既にチャージ済みでないならEffect395を付与
+    data modify storage api: Argument.ID set value 395
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# 演出
+    playsound entity.boat.paddle_water player @a ~ ~ ~ 2 0.5
+    playsound block.conduit.activate player @a ~ ~ ~ 1 1.5

Asset/data/asset/functions/artifact/1620.satelite_drop/using_item/charge/.mcfunction

@@ -0,0 +1,35 @@
+#> asset:artifact/1620.satelite_drop/using_item/charge/
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/using_item/charge/check
+
+#> private
+# @private
+    #declare score_holder $A1620.Stack
+
+# Effect395のスタックを1増やして付与
+    data modify storage api: Argument.ID set value 395
+    function api:entity/mob/effect/get/from_id
+
+    data modify storage api: Argument.ID set value 395
+    execute store result score $A1620.Stack Temporary run data get storage api: Return.Effect.Stack
+    execute store result storage api: Argument.Stack int 1 run scoreboard players add $A1620.Stack Temporary 1
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# スタックが最大ならこの先の処理はスキップ
+    execute if score $A1620.Stack Temporary matches 4.. run return run scoreboard players reset $A1620.Stack Temporary
+
+# MP消費
+    data modify storage api: Argument.Fluctuation set value -40
+    data modify storage api: Argument.DisableLog set value 1b
+    function api:mp/fluctuation
+
+# 演出
+    playsound item.bucket.empty player @a ~ ~ ~ 1 1.3
+    playsound entity.experience_orb.pickup player @a ~ ~ ~ 1 2.0
+    particle wax_off ~ ~0.5 ~ 0.2 0.5 0.2 3 15
+
+# リセット
+    scoreboard players reset $A1620.Stack

Asset/data/asset/functions/artifact/1620.satelite_drop/using_item/charge/check.mcfunction

@@ -0,0 +1,20 @@
+#> asset:artifact/1620.satelite_drop/using_item/charge
+#
+#
+#
+# @within function asset:artifact/1620.satelite_drop/using_item/**
+
+#> private
+# @private
+    #declare score_holder $A1620.Charge
+    #declare score_holder $30
+
+# MPとチャージ時間チェック
+    data modify storage api: Argument.Threshold set value 40
+    function api:mp/check
+    execute store result score $A1620.Charge Temporary run data get storage asset:context UsingItemTime.mainhand
+    scoreboard players operation $A1620.Charge Temporary %= $30 Const
+    execute if score $A1620.Charge Temporary matches 0 if data storage api: Return{IsThresholdOrMore:true} run function asset:artifact/1620.satelite_drop/using_item/charge/
+
+# リセット
+    scoreboard players reset $A1620.Charge

Asset/data/asset/functions/effect/0395.charge_satelite_drop/_/register.mcfunction

@@ -0,0 +1,7 @@
+#> asset:effect/0395.charge_satelite_drop/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:395} run function asset:effect/0395.charge_satelite_drop/register

Asset/data/asset/functions/effect/0395.charge_satelite_drop/register.mcfunction

@@ -0,0 +1,38 @@
+#> asset:effect/0395.charge_satelite_drop/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0395.charge_satelite_drop/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 395
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text": "チャージ・サテライトドロップ", "color": "#a4f1eb"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value ['{"text": "チャージ終了時、段階に応じた数の弾を召喚する"}']
+# 効果時間 (int) (default = API || error)
+    data modify storage asset:effect Duration set value 2147483647
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value
+# 効果時間の操作方法 (default = API || "replace")
+    # data modify storage asset:effect DurationOperation set value
+# スタックの操作方法 (default = API || "replace")
+    # data modify storage asset:effect StackOperation set value
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value
+# 最大スタック (int) (default = 2147483647)
+    data modify storage asset:effect MaxStack set value 3
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value false
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 3
+# エフェクトをUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect Visible set value
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect StackVisible set value
+
+# フィールド