Migrate to Crankcase build logic

build-logic/build.gradle.kts

@@ -0,0 +1,19 @@
+plugins {
+    `kotlin-dsl`
+}
+
+repositories {
+    gradlePluginPortal()
+    maven {
+        name = "EngineHub"
+        url = uri("https://repo.enginehub.org/libs-release/")
+    }
+}
+
+dependencies {
+    implementation(libs.crankcase.checkstyle)
+    implementation(libs.crankcase.java)
+    implementation(libs.crankcase.javaLibrary)
+    implementation(libs.crankcase.licensing)
+    implementation(libs.crankcase.publishing)
+}

build-logic/settings.gradle.kts

@@ -0,0 +1,28 @@
+pluginManagement {
+    repositories {
+        maven {
+            name = "EngineHub"
+            url = uri("https://repo.enginehub.org/libs-release/")
+        }
+        maven {
+            name = "EngineHub Central Mirror"
+            url = uri("https://repo.enginehub.org/internal/maven-central-proxy/")
+        }
+        maven {
+            name = "EngineHub Plugin Portal Mirror"
+            url = uri("https://repo.enginehub.org/internal/plugin-portal-proxy/")
+        }
+    }
+}
+plugins {
+    id("org.enginehub.crankcase.repo-reconfiguration") version "0.1.2"
+}
+dependencyResolutionManagement {
+    versionCatalogs {
+        create("libs") {
+            from(files("../gradle/libs.versions.toml"))
+        }
+    }
+}
+
+rootProject.name = "build-logic"

build-logic/src/main/kotlin/piston.core-ap-conventions.gradle.kts

@@ -0,0 +1,5 @@
+plugins {
+    id("piston.java-conventions")
+}
+
+group = "${providers.gradleProperty("group").get()}.core-ap"

build-logic/src/main/kotlin/piston.java-conventions.gradle.kts

@@ -0,0 +1,31 @@
+plugins {
+    id("org.enginehub.crankcase.checkstyle")
+    id("org.enginehub.crankcase.java-library")
+    id("org.enginehub.crankcase.licensing")
+    id("org.enginehub.crankcase.publishing")
+    jacoco
+}
+
+crankcaseJava {
+    javaRelease = 25
+    // AutoValue & JSpecify annotations are never claimed by a processor
+    disabledLints.add("processing")
+    // exceptions are Serializable via Throwable, but we never serialize them
+    disabledLints.add("serial")
+}
+
+tasks.named<Copy>("processTestResources") {
+    from(isolated.rootProject.projectDirectory.dir("common-test-resources"))
+}
+
+publishing {
+    publications {
+        register<MavenPublication>("maven") {
+            from(components["java"])
+        }
+    }
+}
+
+rootProject.tasks.named("afterReleaseBuild").configure {
+    dependsOn(tasks.named("build"))
+}

build.gradle.kts

@@ -3,12 +3,6 @@ plugins {
     jacoco
 }
 
-configureArtifactory()
-
-repositories {
-    mavenCentral()
-}
-
 release {
     tagTemplate = "v\${version}"
     buildTasks = listOf<String>()

core-ap/annotations/build.gradle.kts

@@ -1,6 +1,8 @@
-applyCoreApConfig()
+plugins {
+    id("piston.core-ap-conventions")
+}
 
 dependencies {
-    "api"(project(":core"))
-    "api"(project(":core-ap:runtime"))
+    api(project(":core"))
+    api(project(":core-ap:runtime"))
 }

core-ap/annotations/src/main/java/org/enginehub/piston/annotation/CommandContainer.java

@@ -42,11 +42,13 @@
      * but if you add an interface that matches existing methods, then
      * those will be overriden, allowing for more generic configuration.
      * </p>
+     *
      * <p>
      * For example, you could add an interface representing the addition
      * of a {@link CommandConditionGenerator} to the registration builder,
      * and then you will be able to inject all builders using a single method.
      * </p>
+     *
      * <p>
      * N.B.: The registration class always implements {@link CommandRegistration},
      * regardless of the content of this array.

core-ap/processor/build.gradle.kts

@@ -1,10 +1,9 @@
 plugins {
-    kotlin("jvm") version "2.4.0"
-    kotlin("kapt") version "2.4.0"
+    alias(libs.plugins.kotlinJvm)
+    alias(libs.plugins.kotlinKapt)
+    id("piston.core-ap-conventions")
 }
 
-applyCoreApConfig()
-
 kapt.includeCompileClasspath = false
 
 tasks.test {
@@ -19,26 +18,26 @@ tasks.test {
 }
 
 dependencies {
-    "implementation"(project(":core"))
-    "implementation"(project(":core-ap:annotations"))
-    "implementation"(project(":core-ap:runtime"))
-    "implementation"(Libs.guava)
-    "implementation"(Libs.javapoet)
-    "implementation"(Libs.autoCommon)
-    "compileOnly"(Libs.autoValueAnnotations)
-    "kapt"(Libs.autoValueProcessor)
-    "compileOnly"(Libs.autoService)
-    "kapt"(Libs.autoService)
+    implementation(project(":core"))
+    implementation(project(":core-ap:annotations"))
+    implementation(project(":core-ap:runtime"))
+    implementation(libs.guava)
+    implementation(libs.javapoet)
+    implementation(libs.autoCommon)
+    compileOnly(libs.autoValueAnnotations)
+    kapt(libs.autoValueProcessor)
+    compileOnly(libs.autoService)
+    kapt(libs.autoService)
 
-    "testImplementation"(kotlin("stdlib"))
-    "testImplementation"(Libs.compileTesting) {
+    testImplementation(kotlin("stdlib"))
+    testImplementation(libs.compileTesting) {
         exclude("junit", "junit")
     }
 
-    "testImplementation"(Libs.mockito)
-    "testRuntimeOnly"(Libs.log4jCore)
-    "testImplementation"(project(":default-impl"))
-    "testCompileOnly"(Libs.autoService)
-    "kaptTest"(Libs.autoService)
-    "kaptTest"(project(":core-ap:processor"))
+    testImplementation(libs.mockito)
+    testRuntimeOnly(libs.log4jCore)
+    testImplementation(project(":default-impl"))
+    testCompileOnly(libs.autoService)
+    kaptTest(libs.autoService)
+    kaptTest(project(":core-ap:processor"))
 }