OS_Hacking/linker.ld at master · wangjild/OS_Hacking · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
OUTPUT_FORMAT("elf32-i386")
ENTRY (loader)
KERNEL_OFFSET   = 0xC0000000;  /* 3G */
KERNEL_PHYADDR  = 0x00100000;  /* 1M */
KERNEL_VIRADDR  = KERNEL_OFFSET +  KERNEL_PHYADDR; /* 3G 1M */

SECTIONS{
	. = KERNEL_PHYADDR;
    _kernel_image_start = . + KERNEL_OFFSET;
    .mbh.text ALIGN(0x4): {
        *(.mbh.text)
    }

    /* Higher Half Bare Bones */
    . += KERNEL_OFFSET;
    .text   ALIGN(0x4) : AT(ADDR(.text) - KERNEL_OFFSET) {
		*(.text)
	}
	.rodata	ALIGN (0x1000) : AT(ADDR(.rodata) - KERNEL_OFFSET) {
		*(.rodata)
	}
	.data	ALIGN (0x1000) : AT(ADDR(.data) - KERNEL_OFFSET) {
		*(.data)
	}
	.bss : AT(ADDR(.bss) - KERNEL_OFFSET) {
		sbss = .;
		*(COMMON)
		*(.bss)
		ebss = .;
	}

    /* Page Dir */
    .pgdir.data   ALIGN   (0x01000) : AT(ADDR(.pgdir.data) - KERNEL_OFFSET) {
        *(.pgdir.data)
    }

    /* Page Table */
    .pgtbl.data   ALIGN   (0x01000) : AT(ADDR(.pgtbl.data) - KERNEL_OFFSET) {
        *(.pgtbl.data)
    }

    _kernel_image_end = . ;

}