EXTRA

   10PROCheader("?")
   20question%=P%
   30FORo%=0TO3STEP3
   40P%=question%
   50[:OPTo%
   60JSRfetch%
   70JSRdot%
   80RTS
   90]:NEXTo%
  100PROCheader(CHR$(46)+CHR$(34))
  110dotquote%=P%
  120FORo%=0TO3STEP3
  130P%=dotquote%
  140[:OPTo%
  150JSRqcomp%
  160OPT FNliteral(slit%)
  170JSRjsrc%
  180OPT FNliteral(&22)
  190JSRword%
  200JSRhere%
  210JSRcfetch%
  220JSRoneplus%
  230JSRallot%
  240OPT FNliteral(count%)
  250JSRjsrc%
  260OPT FNliteral(type%)
  270JSRjsrc%
  280RTS
  290]:NEXTo%
  300PROCsetbit(6,last%)
  310PROCheader(".(")
  320dotb%=P%
  330FORo%=0TO3STEP3
  340P%=dotb%
  350[:OPTo%
  360JSRqexec%
  370OPT FNliteral(&29)
  380JSRword%
  390JSRhere%
  400JSRcount%
  410JSRtype%
  420RTS
  430]:NEXTo%
  440PROCsetbit(6,last%)
  450PROCheader("(")
  460comment%=P%
  470FORo%=0TO3STEP3
  480P%=comment%
  490[:OPTo%
  500OPT FNliteral(&29)
  510JSRword%
  520RTS
  530]:NEXTo%
  540PROCsetbit(6,last%)
  550PROCheader("os'")
  560os%=P%
  570FORo%=0TO3STEP3
  580P%=os%
  590[:OPTo%
  600OPT FNliteral(&27)
  610JSRword%
  620JSRhere%
  630JSRoscli%
  640RTS
  650]:NEXTo%
  660PROCheader("ascii")
  670ascii%=P%
  680FORo%=0TO3STEP3
  690P%=ascii%
  700[:OPTo%
  710OPT FNliteral(&20)
  720JSRword%
  730JSRhere%
  740JSRoneplus%
  750JSRcfetch%
  760JSRliteral%
  770RTS
  780]:NEXTo%
  790PROCsetbit(6,last%)
  800PROCheader("decimal")
  810dec%=P%
  820FORo%=0TO3STEP3
  830P%=dec%
  840[:OPTo%
  850OPT FNliteral(&0A)
  860JSRbase%
  870JSRstore%
  880RTS
  890]:NEXTo%
  900PROCheader("hex")
  910hex%=P%
  920FORo%=0TO3STEP3
  930P%=hex%
  940[:OPTo%
  950OPT FNliteral(&10)
  960JSRbase%
  970JSRstore%
  980RTS
  990]:NEXTo%
 1000PROCheader("binary")
 1010bin%=P%
 1020FORo%=0TO3STEP3
 1030P%=bin%
 1040[:OPTo%
 1050OPT FNliteral(&02)
 1060JSRbase%
 1070JSRstore%
 1080RTS
 1090]:NEXTo%
 1100PROCheader("compile")
 1110compile%=P%
 1120FORo%=0TO3STEP3
 1130P%=compile%
 1140[:OPTo%
 1150JSRqcomp%
 1160JSRmfind%
 1170JSRnot%
 1180OPT FNliteral(emislex%)
 1190JSRqerror%
 1200JSRdrop%
 1210OPT FNliteral(lit%)
 1220JSRjsrc%
 1230JSRcomma%
 1240OPT FNliteral(jsrc%)
 1250JSRjsrc%
 1260RTS
 1270]:NEXTo%
 1280PROCsetbit(6,last%)
 1290PROCheader("[compile]")
 1300sqrcompile%=P%
 1310FORo%=0TO3STEP3
 1320P%=sqrcompile%
 1330[:OPTo%
 1340JSRqcomp%
 1350JSRmfind%
 1360JSRnot%
 1370OPT FNliteral(emislex%)
 1380JSRqerror%
 1390JSRdrop%
 1400JSRjsrc%
 1410RTS
 1420]:NEXTo%
 1430PROCsetbit(6,last%)
 1440PROCheader("if")
 1450if%=P%
 1460FORo%=0TO3STEP3
 1470P%=if%
 1480[:OPTo%
 1490JSRqcomp%
 1500OPT FNliteral(branch%)
 1510JSRjsrc%
 1520OPT FNliteral(&00)
 1530JSRbeqc%
 1540JSRhere%
 1550OPT FNliteral(&02)
 1560RTS
 1570]:NEXTo%
 1580PROCsetbit(6,last%)
 1590PROCheader("endif")
 1600endif%=P%
 1610FORo%=0TO3STEP3
 1620P%=endif%
 1630[:OPTo%
 1640JSRqcomp%
 1650OPT FNliteral(&02)
 1660JSRqpairs%
 1670JSRhere%
 1680JSRover%
 1690JSRminusadd%
 1700JSRswap%
 1710JSRoneminus%
 1720JSRcstore%
 1730RTS
 1740]:NEXTo%
 1750PROCsetbit(6,last%)
 1760PROCheader("else")
 1770else%=P%
 1780FORo%=0TO3STEP3
 1790P%=else%
 1800[:OPTo%
 1810OPT FNliteral(&02)
 1820JSRqcomp%
 1830JSRqpairs%
 1840JSRclcc%
 1850OPT FNliteral(&00)
 1860JSRbccc%
 1870JSRhere%
 1880JSRover%
 1890JSRminusadd%
 1900JSRswap%
 1910JSRoneminus%
 1920JSRcstore%
 1930JSRhere%
 1940OPT FNliteral(&02)
 1950RTS
 1960]:NEXTo%
 1970PROCsetbit(6,last%)
 1980PROCheader("back")
 1990back%=P%
 2000FORo%=0TO3STEP3
 2010P%=back%
 2020[:OPTo%
 2030JSRhere%
 2040JSRtwoplus%
 2050JSRminusadd%
 2060RTS
 2070]:NEXTo%
 2080PROCheader("begin")
 2090begin%=P%
 2100FORo%=0TO3STEP3
 2110P%=begin%
 2120[:OPTo%
 2130JSRqcomp%
 2140JSRhere%
 2150OPT FNliteral(&01)
 2160RTS
 2170]:NEXTo%
 2180PROCsetbit(6,last%)
 2190PROCheader("until")
 2200until%=P%
 2210FORo%=0TO3STEP3
 2220P%=until%
 2230[:OPTo%
 2240JSRqcomp%
 2250OPT FNliteral(&01)
 2260JSRqpairs%
 2270OPT FNliteral(branch%)
 2280JSRjsrc%
 2290JSRback%
 2300JSRbeqc%
 2310RTS
 2320]:NEXTo%
 2330PROCsetbit(6,last%)
 2340PROCheader("again")
 2350again%=P%
 2360FORo%=0TO3STEP3
 2370P%=again%
 2380[:OPTo%
 2390JSRqcomp%
 2400OPT FNliteral(&01)
 2410JSRqpairs%
 2420JSRclcc%
 2430JSRback%
 2440JSRbccc%
 2450RTS
 2460]:NEXTo%
 2470PROCsetbit(6,last%)
 2480PROCheader("while")
 2490while%=P%
 2500FORo%=0TO3STEP3
 2510P%=while%
 2520[:OPTo%
 2530JSRqcomp%
 2540OPT FNliteral(branch%)
 2550JSRjsrc%
 2560OPT FNliteral(&00)
 2570JSRbeqc%
 2580JSRhere%
 2590OPT FNliteral(&02)
 2600RTS
 2610]:NEXTo%
 2620PROCsetbit(6,last%)
 2630PROCheader("repeat")
 2640repeat%=P%
 2650FORo%=0TO3STEP3
 2660P%=repeat%
 2670[:OPTo%
 2680JSRqcomp%
 2690JSRrot%
 2700OPT FNliteral(&01)
 2710JSRqpairs%
 2720JSRrot%
 2730JSRclcc%
 2740JSRback%
 2750JSRbccc%
 2760OPT FNliteral(&02)
 2770JSRqpairs%
 2780JSRhere%
 2790JSRover%
 2800JSRminusadd%
 2810JSRswap%
 2820JSRoneminus%
 2830JSRcstore%
 2840RTS
 2850]:NEXTo%
 2860PROCsetbit(6,last%)
 2870PROCheader("do")
 2880do%=P%
 2890FORo%=0TO3STEP3
 2900P%=do%
 2910[:OPTo%
 2920JSRqcomp%
 2930OPT FNliteral(bdo%)
 2940JSRjsrc%
 2950JSRhere%
 2960OPT FNliteral(&03)
 2970RTS
 2980]:NEXTo%
 2990PROCsetbit(6,last%)
 3000PROCheader("loop")
 3010loop%=P%
 3020FORo%=0TO3STEP3
 3030P%=loop%
 3040[:OPTo%
 3050JSRqcomp%
 3060OPT FNliteral(&03)
 3070JSRqpairs%
 3080OPT FNliteral(bloop%)
 3090JSRjsrc%
 3100JSRback%
 3110JSRbccc%
 3120OPT FNliteral(adrop%)
 3130JSRjsrc%
 3140OPT FNliteral(adrop%)
 3150JSRjsrc%
 3160RTS
 3170]:NEXTo%
 3180PROCsetbit(6,last%)
 3190PROCheader("+loop")
 3200plusloop%=P%
 3210FORo%=0TO3STEP3
 3220P%=plusloop%
 3230[:OPTo%
 3240JSRqcomp%
 3250OPT FNliteral(&03)
 3260JSRqpairs%
 3270OPT FNliteral(bplusloop%)
 3280JSRjsrc%
 3290JSRback%
 3300JSRbccc%
 3310OPT FNliteral(adrop%)
 3320JSRjsrc%
 3330OPT FNliteral(adrop%)
 3340JSRjsrc%
 3350RTS
 3360]:NEXTo%
 3370PROCsetbit(6,last%)
 3380OSCLI("EXEC E.EXTRA")
 3390END
 3400DEFPROCheader(name$)
 3410PRINT:PRINT
 3420PRINT"  *** ";~P%;" nfa '";name$;"'"
 3430LETxhere%=P%
 3440LETspan%=LEN(name$)
 3450?P%=span%
 3460PROCsetbit(7,P%)
 3470LETP%=P%+1
 3480IFspan% > length%THENspan%=length%
 3490FORi%=1TOspan%
 3500?P%=ASC(MID$(name$,i%,1))
 3510LETP%=P%+1
 3520NEXTi%
 3530PRINT"  *** ";~P%;" lfa (";~last%;")"
 3540PROCsetbit(7,P%-1)
 3550PROCpoke(last%,P%)
 3560LETP%=P%+2
 3570LETlast%=xhere%
 3580LETlabel%=label%+1
 3590PRINT:PRINT
 3600ENDPROC
 3610DEFPROCsetbit(bit%,addr%)
 3620?addr%=?addr%OR(2^bit%)
 3630ENDPROC
 3640DEFPROCpoke(val%,addr%)
 3650?addr%=val%MOD256
 3660?(addr%+1)=val%DIV256
 3670ENDPROC
 3680DEFFNliteral(value%):[:OPTo%:JSRlit%:]:PROCpoke(value%,P%):P%=P%+2:=o%