liblo-sys/flake.nix at main · no-materials/liblo-sys · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
{
  description = "Dev flake for liblo-sys FFI crate";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";

    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };

    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = inputs.flake-utils.lib.defaultSystems;

      perSystem =
        {
          self',
          pkgs,
          system,
          lib,
          ...
        }:
        let
          fnx = inputs.fenix.packages.${system};

          mkRustDeriv =
            fnx-version: extra-components:
            let
              std-components = [
                fnx-version.cargo
                fnx-version.clippy
                fnx-version.rust-src
                fnx-version.rustc
                fnx-version.rust-analyzer

                # it's generally recommended to use nightly rustfmt
                fnx.complete.rustfmt
              ];
              all-components = std-components ++ extra-components;
            in
            fnx.combine all-components;

          stableRust = mkRustDeriv fnx.stable [ ];
          nightlyRust = mkRustDeriv fnx.complete [ ];
          wasmRust = mkRustDeriv fnx.stable [ fnx.targets.wasm32-unknown-unknown.stable.rust-std ];

          generalPkgs = with pkgs; [
            pkg-config
            alsa-lib
            openssl
            rustPlatform.bindgenHook

            # used for non-bundled build
            liblo

            # used for bundled build
            autoconf
            automake
            autogen
            libtool
          ];
          nightlyPkgs = [ ];
          wasmPkgs = [ ];

          mkName = name: name + "-dev-shell";
          mkPersonalShell =
            { shellName, shellPackages }:
            pkgs.mkShell rec {
              name = mkName shellName;
              packages = generalPkgs ++ shellPackages;
              LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath packages;
            };
        in
        {

          formatter = pkgs.nixfmt-rfc-style;
          devShells.default = self'.devShells.rust-stable;
          devShells = {
            rust-stable = mkPersonalShell {
              shellName = "rust-stable";
              shellPackages = [ stableRust ];
            };
            rust-nightly = mkPersonalShell {
              shellName = "rust-nightly";
              shellPackages = nightlyPkgs ++ [ nightlyRust ];
            };
            rust-wasm = mkPersonalShell {
              shellName = "rust-wasm";
              shellPackages = wasmPkgs ++ [ wasmRust ];
            };
          };
        };
    };
}