build.gradle

import org.apache.tools.ant.taskdefs.condition.Os

plugins {
    id "application"
    id "io.github.jwharm.flatpak-gradle-generator" version "1.6.0"
    id "com.gradleup.shadow" version "9.3.1"
}

repositories {
    maven { url = "build/repository" } // used by flatpak-builder
    mavenCentral()
}

dependencies {
    implementation "org.java-gi:adw:0.14.1"
}

// Generate a file with all dependency urls for the offline flatpak build
tasks.flatpakGradleGenerator {
    outputFile.set(file("$rootDir/data/maven-dependencies.json"))
    downloadDirectory.set("build/repository")
    excludeConfigurations = ['testCompileClasspath', 'testRuntimeClasspath']
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(25)
    }
}

application {
    applicationName = "example"
    mainClass = "org.domain.Example"

    // Allow native access
    applicationDefaultJvmArgs += "--enable-native-access=ALL-UNNAMED"

    // Add common library directories to the library lookup path
    if (Os.isFamily(Os.FAMILY_MAC))
        applicationDefaultJvmArgs += [
            "-Djavagi.path=/opt/homebrew/lib",
            "-XstartOnFirstThread"
        ]
    else if (Os.isFamily(Os.FAMILY_WINDOWS))
        applicationDefaultJvmArgs += [
            "-Djavagi.path=C:/msys64/mingw64/bin"
        ]
    else
        applicationDefaultJvmArgs += [
            "-Djavagi.path=/usr/lib/x86_64-linux-gnu:/lib64:/usr/lib64:/lib:/usr/lib"
        ]
}

// The "devel" profile will add the "devel" CSS class to the main window.
run {
    environment "PROFILE", "devel"
}

/* These tasks can be used to manually compile the blueprint files into a
 * gresource bundle.
 *
 * Make sure that "blueprint-compiler" and "glib-compile-resources" are
 * installed. They should be included in the GTK development packages for your
 * operating system (for example, on Ubuntu, install the blueprint-compiler and
 * libglib2.0-dev packages).
 */
tasks.register("compileBlueprints", Exec) {
    def files = fileTree("src/main/blueprint") {
        include "**/*.blp"
    }.files

    group = "build"
    commandLine "blueprint-compiler",
            "batch-compile",
            "build/generated/ui",
            "src/main/blueprint",
            *files.toList().toArray()
}

tasks.register("compileResources", Exec) {
    def resourceFile = "org.domain.Example.gresource"

    dependsOn compileBlueprints
    group = "build"
    commandLine "glib-compile-resources",
                "--sourcedir=build/generated/ui",
                "--target=build/generated/org.domain.Example.gresource",
                "data/org.domain.Example.gresource.xml"
}