java-sdk/build.gradle.kts at main · agentruntimecontrolprotocol/java-sdk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
plugins {
    id("com.diffplug.spotless") version "6.25.0" apply false
}

allprojects {
    group = "dev.arcp"
    version = "1.0.0-SNAPSHOT"

    repositories {
        mavenCentral()
    }
}

subprojects {
    plugins.withId("java-library") {
        extensions.configure<JavaPluginExtension> {
            toolchain {
                languageVersion.set(JavaLanguageVersion.of(21))
            }
            withSourcesJar()
            withJavadocJar()
        }
        tasks.withType<JavaCompile>().configureEach {
            options.release.set(21)
            options.encoding = "UTF-8"
            options.compilerArgs.addAll(
                listOf(
                    "-Xlint:all",
                    "-Xlint:-processing",
                    "-Xlint:-requires-automatic",
                    "-parameters",
                ),
            )
        }
        tasks.withType<Test>().configureEach {
            useJUnitPlatform()
        }
        tasks.withType<Javadoc>().configureEach {
            (options as? StandardJavadocDocletOptions)?.apply {
                addStringOption("Xdoclint:none", "-quiet")
                encoding = "UTF-8"
                charSet = "UTF-8"
            }
        }
        apply(plugin = "com.diffplug.spotless")
        configure<com.diffplug.gradle.spotless.SpotlessExtension> {
            java {
                googleJavaFormat()
                removeUnusedImports()
            }
        }
    }

    // Shared publishing metadata. Per-subproject build files still own the
    // artifactId and one-line description; everything else (licence, SCM,
    // developer, signing) is configured once here.
    plugins.withId("maven-publish") {
        apply(plugin = "signing")

        afterEvaluate {
            extensions.configure<PublishingExtension> {
                publications.withType<MavenPublication>().configureEach {
                    pom {
                        url.set("https://github.com/nficano/arpc")
                        licenses {
                            license {
                                name.set("Apache-2.0")
                                url.set("https://www.apache.org/licenses/LICENSE-2.0.txt")
                                distribution.set("repo")
                            }
                        }
                        developers {
                            developer {
                                id.set("nficano")
                                name.set("Nick Ficano")
                                email.set("nficano@gmail.com")
                            }
                        }
                        scm {
                            url.set("https://github.com/nficano/arpc")
                            connection.set("scm:git:https://github.com/nficano/arpc.git")
                            developerConnection.set("scm:git:ssh://git@github.com/nficano/arpc.git")
                        }
                        issueManagement {
                            system.set("GitHub")
                            url.set("https://github.com/nficano/arpc/issues")
                        }
                    }
                }
            }

            // Signing is only wired when the developer has supplied a PGP key.
            // Local builds and CI without credentials skip it silently.
            // Note: GitHub Actions injects "" for unset secrets, so normalise
            // blank strings to null before the presence check.
            extensions.configure<org.gradle.plugins.signing.SigningExtension> {
                val signingKey = (findProperty("signingKey") as String?)?.ifBlank { null }
                        ?: System.getenv("GPG_SIGNING_KEY")?.ifBlank { null }
                val signingPassword = (findProperty("signingPassword") as String?)?.ifBlank { null }
                        ?: System.getenv("GPG_SIGNING_PASSWORD")?.ifBlank { null }
                isRequired = signingKey != null && signingPassword != null
                if (isRequired) {
                    useInMemoryPgpKeys(signingKey, signingPassword)
                    val publishing =
                            extensions.getByType(PublishingExtension::class.java)
                    sign(publishing.publications)
                }
            }
        }
    }
}