SleepLess/build.gradle at 1.12.2 · TheComputerizer/SleepLess · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
//file:noinspection GroovyAssignabilityCheck
import static org.gradle.api.file.DuplicatesStrategy.INCLUDE

plugins {
    id 'net.minecraftforge.gradle' version '6.+'
    id 'wtf.gofancy.fancygradle' version '1.+'
    id 'org.spongepowered.mixin' version '0.+'
}

fancyGradle {
    patches {
        resources
        coremods
        codeChickenLib
        asm
        mergetool
    }
}


version = "$minecraft_version-$mod_version"
group = maven_group

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of 8
    }
}

minecraft {
    mappings channel: 'stable', version: mappings_version
    accessTransformer = file 'src/main/resources/META-INF/sleepless_at.cfg'
    def args = [ '-Dmixin.debug.export=true', '-Dmixin.hotSwap=true', '-Dmixin.checks.interfaces=true' ]
    runs {
        configureEach {
            property 'forge.logging.markers', 'SCAN,REGISTRIES,REGISTRYDUMP'
            property 'forge.logging.console.level', 'debug'
            jvmArgs args
        }
        client {
            workingDirectory file('run_client')
        }
        server {
            workingDirectory file('run_server')
        }
    }
}

repositories {
    maven {
        name = 'CurseMaven'
        url = uri 'https://curse.cleanroommc.com'
        content {
            includeGroup 'curse.maven'
        }
    }
}

dependencies {
    //noinspection VulnerableLibrariesLocal
    minecraft "net.minecraftforge:forge:$minecraft_version-$forge_version"

    //required
    implementation "curse.maven:the-impossible-library-661115:$til_version"

    //runtime stuff
    runtimeOnly fg.deobf("curse.maven:had-enough-items-557549:$hei_version")
    runtimeOnly fg.deobf("curse.maven:the-one-probe-245211:$top_version")

    //mixin stuff
    implementation "curse.maven:mixin-booter-419286:$mixinbooter_version"
    implementation "curse.maven:mixin-booter-419286:$mixinbooter_sources"
    implementation "curse.maven:mixin-booter-419286:$mixinbooter_javadoc"
    annotationProcessor "org.spongepowered:mixin:$mixin_version:processor"
}

processResources {
    duplicatesStrategy = INCLUDE
    inputs.property "version", version
    inputs.property "mcversion", minecraft_version
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand 'version': version, 'mcversion': minecraft_version
    }
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

mixin {
    add sourceSets.main, "sleepless.refmap.json"
}

jar {
    archivesBaseName = base_name
    manifest {
        attributes([
                'FMLAT': 'sleepless_at.cfg',
                'FMLCorePlugin': 'mods.thecomputerizer.sleepless.core.VanillaMixinLoader',
                'FMLCorePluginContainsFMLMod': true,
                'ForceLoadAsMod': true,
                'TweakClass': 'org.spongepowered.asm.launch.MixinTweaker'
        ])
    }
}