diff --git a/Asset/data/asset/functions/artifact/1643.jet_booster/give/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1643.jet_booster/give/1.trigger.mcfunction
new file mode 100644
index 0000000000..21975dd705
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1643.jet_booster/give/1.trigger.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1643.jet_booster/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1643} run function asset:artifact/1643.jet_booster/give/2.give
\ No newline at end of file
diff --git a/Asset/data/asset/functions/artifact/1643.jet_booster/give/2.give.mcfunction b/Asset/data/asset/functions/artifact/1643.jet_booster/give/2.give.mcfunction
new file mode 100644
index 0000000000..cf3633a467
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1643.jet_booster/give/2.give.mcfunction
@@ -0,0 +1,68 @@
+#> asset:artifact/1643.jet_booster/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1643.jet_booster/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1643
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:carrot_on_a_stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text": "ジェットブースター", "color": "blue"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text": "使用してから5秒後、爆発をして向いている方向に吹っ飛ぶ。"}', '{"text": "MPが使用時と比べて低いほど攻撃範囲、威力、推進力が上昇する。"}', '{"text": "マナの準位差を利用して動くブースター。", "color": "gray"}', '{"text": "燃料の貯蓄こそできないが、爆発的な出力を誇る。", "color": "gray"}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onClick"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value [200,1000]
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Physical]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Fire]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "every"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value "???"
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 100
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    data modify storage asset:artifact LocalCooldown set value 600
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    # data modify storage asset:artifact TypeCooldown.Type set value
+    # data modify storage asset:artifact TypeCooldown.Duration set value
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Urban", "Rumor", "Wi-ki"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give
diff --git a/Asset/data/asset/functions/artifact/1643.jet_booster/register.mcfunction b/Asset/data/asset/functions/artifact/1643.jet_booster/register.mcfunction
new file mode 100644
index 0000000000..4eec1bfae5
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1643.jet_booster/register.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1643.jet_booster/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[4] append value [1643]
+data modify storage asset:artifact RarityRegistryWithColor.Red[4] append value [1643]
diff --git a/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/1.trigger.mcfunction
new file mode 100644
index 0000000000..a57b96c155
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/1.trigger.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1643.jet_booster/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1643} run function asset:artifact/1643.jet_booster/trigger/2.check_condition
\ No newline at end of file
diff --git a/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/2.check_condition.mcfunction b/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/2.check_condition.mcfunction
new file mode 100644
index 0000000000..cc231a4abc
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/2.check_condition.mcfunction
@@ -0,0 +1,16 @@
+#> asset:artifact/1643.jet_booster/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1643.jet_booster/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+# 他にアイテム等確認する場合はここに書く
+# Effect 408が既にあるならキャンセル
+    data modify storage api: Argument.ID set value 408
+    function api:entity/mob/effect/get/from_id
+    execute if data storage api: Return.Effect run tag @s remove CanUsed
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1643.jet_booster/trigger/3.main
diff --git a/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/3.main.mcfunction b/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/3.main.mcfunction
new file mode 100644
index 0000000000..5775f14ee9
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1643.jet_booster/trigger/3.main.mcfunction
@@ -0,0 +1,36 @@
+#> asset:artifact/1643.jet_booster/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1643.jet_booster/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# ここから先は神器側の効果の処理を書く
+# Effect 408を付与、MP計測開始
+    data modify storage api: Argument.ID set value 408
+
+    # 効果時間
+        data modify storage api: Argument.Duration set value 100
+
+    ## 攻撃情報
+    # 最低ベクトル / 最低ダメージ(倍率2)
+        data modify storage api: Argument.FieldOverride.MinMagnitude set value 100
+    # 最大ベクトル / 最大ダメージ(倍率2)
+        data modify storage api: Argument.FieldOverride.MaxMagnitude set value 500
+
+    # MP差1ごとのダメージ(倍率0.01)
+        data modify storage api: Argument.FieldOverride.Multiplier set value 200
+
+    # 攻撃範囲とMP消費の基準値
+        data modify storage api: Argument.FieldOverride.Range set value {0:3,1:6,2:8}
+        data modify storage api: Argument.FieldOverride.Border set value {1:100,2:150}
+
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# 演出
+    playsound entity.tnt.primed player @a ~ ~ ~ 1.0 0.5
+    playsound ogg:block.vault.eject3 player @a ~ ~ ~ 1.0 1.0
+    particle campfire_signal_smoke ~ ~1 ~ 0.1 0.5 0.1 0.05 10
diff --git a/Asset/data/asset/functions/effect/0408.fueling/_/end.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/_/end.mcfunction
new file mode 100644
index 0000000000..28c5135210
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/_/end.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0408.fueling/_/end
+#
+# Effectの効果の終了時に実行されるfunction
+#
+# @within tag/function asset:effect/end
+
+execute if data storage asset:context {id:408} run function asset:effect/0408.fueling/end/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0408.fueling/_/given.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/_/given.mcfunction
new file mode 100644
index 0000000000..7f384c4ebb
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/_/given.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0408.fueling/_/given
+#
+# Effectが付与された時に実行されるfunction
+#
+# @within tag/function asset:effect/given
+
+execute if data storage asset:context {id:408} run function asset:effect/0408.fueling/given/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0408.fueling/_/register.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/_/register.mcfunction
new file mode 100644
index 0000000000..496ebcd024
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/_/register.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0408.fueling/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:408} run function asset:effect/0408.fueling/register
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0408.fueling/_/tick.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/_/tick.mcfunction
new file mode 100644
index 0000000000..b9ed6582a5
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/_/tick.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0408.fueling/_/tick
+#
+# Effectが発動している間毎tick実行されるfunction
+#
+# @within tag/function asset:effect/tick
+
+execute if data storage asset:context {id:408} run function asset:effect/0408.fueling/tick/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/effect/0408.fueling/end/.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/end/.mcfunction
new file mode 100644
index 0000000000..249a24061c
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/end/.mcfunction
@@ -0,0 +1,66 @@
+#> asset:effect/0408.fueling/end/
+#
+# Effectの効果が切れた時の処理
+#
+# @within function asset:effect/0408.fueling/_/end
+
+#> Private
+# @private
+    #declare score_holder $E0408.Multiplier
+    #declare score_holder $E0408.Magnitude
+    #declare score_holder $E0408.MinMagnitude
+    #declare score_holder $E0408.MaxMagnitude
+    #declare score_holder $E0408.MP
+    #declare score_holder $E0408.Border1
+    #declare score_holder $E0408.Border2
+
+# 使用時とのMP差に応じた強さのPlayerMotionを適用
+    function api:mp/get_current
+    execute store result score $E0408.MP Temporary run data get storage api: Return.CurrentMP
+    execute store result score $E0408.Magnitude Temporary run data get storage asset:context this.InitialMP
+    scoreboard players operation $E0408.Magnitude Temporary -= $E0408.MP Temporary
+
+    #最低MinMagnitudeは飛ぶ
+    execute store result score $E0408.MinMagnitude Temporary run data get storage asset:context this.MinMagnitude
+    execute if score $E0408.Magnitude Temporary matches 1.. run scoreboard players operation $E0408.Magnitude Temporary += $E0408.MinMagnitude Temporary
+    execute if score $E0408.Magnitude Temporary matches ..0 run scoreboard players operation $E0408.Magnitude Temporary = $E0408.MinMagnitude Temporary
+
+    execute store result storage lib: Argument.VectorMagnitude double 0.01 run scoreboard players get $E0408.Magnitude Temporary
+    function lib:motion/looking
+
+
+# 攻撃情報(最低でMinMagnitude * Multiplier)
+    execute store result score $E0408.MaxMagnitude Temporary run data get storage asset:context this.MaxMagnitude
+    scoreboard players operation $E0408.Magnitude Temporary < $E0408.MaxMagnitude Temporary
+
+    execute store result score $E0408.Multiplier Temporary run data get storage asset:context this.Multiplier
+    execute store result storage api: Argument.Damage double 0.01 run scoreboard players operation $E0408.Multiplier Temporary *= $E0408.Magnitude Temporary
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Fire"
+    function api:damage/modifier
+
+    function api:damage/single_damage_session/open
+
+# 攻撃範囲も可変
+    execute store result score $E0408.Border1 Temporary run data get storage asset:context this.Border.1 2
+    execute store result score $E0408.Border2 Temporary run data get storage asset:context this.Border.2 2
+
+    execute if score $E0408.Magnitude Temporary < $E0408.Border1 Temporary positioned ^ ^ ^-2 run function asset:effect/0408.fueling/end/attack/1.m with storage asset:context this.Range
+    execute if score $E0408.Magnitude Temporary >= $E0408.Border1 Temporary if score $E0408.Magnitude Temporary < $E0408.Border2 Temporary positioned ^ ^ ^-2 run function asset:effect/0408.fueling/end/attack/2.m with storage asset:context this.Range
+    execute if score $E0408.Magnitude Temporary >= $E0408.Border2 Temporary positioned ^ ^ ^-2 run function asset:effect/0408.fueling/end/attack/3.m with storage asset:context this.Range
+
+    function api:damage/reset
+    function api:damage/single_damage_session/close
+
+# 共通演出
+    playsound entity.firework_rocket.launch player @a ~ ~ ~ 2.0 0.5
+    playsound block.note_block.bit player @s ~ ~ ~ 1.0 2.0
+
+# リセット
+    scoreboard players reset $E0408.Multiplier
+    scoreboard players reset $E0408.Magnitude
+    scoreboard players reset $E0408.MinMagnitude
+    scoreboard players reset $E0408.MaxMagnitude
+    scoreboard players reset $E0408.MP
+    scoreboard players reset $E0408.Border1
+    scoreboard players reset $E0408.Border2
diff --git a/Asset/data/asset/functions/effect/0408.fueling/end/attack/1.m.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/end/attack/1.m.mcfunction
new file mode 100644
index 0000000000..4623f83b0f
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/end/attack/1.m.mcfunction
@@ -0,0 +1,11 @@
+#> asset:effect/0408.fueling/end/attack/1.m
+#
+#
+#
+# @within function asset:effect/0408.fueling/end/
+
+    $execute as @e[type=#lib:living_without_player,tag=Enemy,distance=..$(0)] run function api:damage/
+
+# 演出
+    playsound ogg:random.explode4 player @a ~ ~ ~ 1 2
+    particle flame ~ ~ ~ 1 0.0 1 0.01 50
diff --git a/Asset/data/asset/functions/effect/0408.fueling/end/attack/2.m.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/end/attack/2.m.mcfunction
new file mode 100644
index 0000000000..ff02004fd1
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/end/attack/2.m.mcfunction
@@ -0,0 +1,13 @@
+#> asset:effect/0408.fueling/end/attack/2.m
+#
+#
+#
+# @within function asset:effect/0408.fueling/end/
+
+
+    $execute as @e[type=#lib:living_without_player,tag=Enemy,distance=..$(1)] run function api:damage/
+
+# 演出
+    playsound ogg:random.explode4 player @a ~ ~ ~ 1 1.5
+    particle flame ~ ~ ~ 2 0.0 2 0.01 100
+    particle explosion ^ ^ ^4 0 0 0 1 1
diff --git a/Asset/data/asset/functions/effect/0408.fueling/end/attack/3.m.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/end/attack/3.m.mcfunction
new file mode 100644
index 0000000000..29027e8d07
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/end/attack/3.m.mcfunction
@@ -0,0 +1,12 @@
+#> asset:effect/0408.fueling/end/attack/3.m
+#
+#
+#
+# @within function asset:effect/0408.fueling/end/
+
+    $execute as @e[type=#lib:living_without_player,tag=Enemy,distance=..$(2)] run function api:damage/
+
+# 演出
+    playsound ogg:random.explode4 player @a ~ ~ ~ 1 1.5
+    particle flame ~ ~ ~ 4 0.0 4 0.01 150
+    particle explosion_emitter ^ ^ ^6 0 0 0 1 1
diff --git a/Asset/data/asset/functions/effect/0408.fueling/given/.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/given/.mcfunction
new file mode 100644
index 0000000000..d50abfc4e9
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/given/.mcfunction
@@ -0,0 +1,9 @@
+#> asset:effect/0408.fueling/given/
+#
+# Effectが付与された時の処理
+#
+# @within function asset:effect/0408.fueling/_/given
+
+# 現在MPを記憶
+    function api:mp/get_current
+    data modify storage asset:context this.InitialMP set from storage api: Return.CurrentMP
diff --git a/Asset/data/asset/functions/effect/0408.fueling/register.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/register.mcfunction
new file mode 100644
index 0000000000..d580dafaa4
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/register.mcfunction
@@ -0,0 +1,40 @@
+#> asset:effect/0408.fueling/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0408.fueling/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 408
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text": "発射用意", "color": "#fa9514"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value ['{"text": "効果開始時と終了時のMP差を推進力に変える"}']
+# 効果時間 (int) (default = API || error)
+    # data modify storage asset:effect Duration set value
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value
+# 効果時間の操作方法 (default = API || "replace")
+    # data modify storage asset:effect DurationOperation set value
+# スタックの操作方法 (default = API || "replace")
+    # data modify storage asset:effect StackOperation set value
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value
+# 最大スタック (int) (default = 2147483647)
+    # data modify storage asset:effect MaxStack set value
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value false
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 3
+# エフェクトをUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect Visible set value
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    data modify storage asset:effect StackVisible set value false
+
+# フィールド
+    data modify storage asset:effect Field.InitialMP set value -1
+    data modify storage asset:effect Field.Interval set value 20
diff --git a/Asset/data/asset/functions/effect/0408.fueling/tick/.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/tick/.mcfunction
new file mode 100644
index 0000000000..2ba8719b16
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/tick/.mcfunction
@@ -0,0 +1,9 @@
+#> asset:effect/0408.fueling/tick/
+#
+# Effectのtick処理
+#
+# @within function asset:effect/0408.fueling/_/tick
+
+# Interval減算
+    execute store result storage asset:context this.Interval int 0.9999999999 run data get storage asset:context this.Interval
+    execute if data storage asset:context this{Interval:0} run function asset:effect/0408.fueling/tick/countdown
diff --git a/Asset/data/asset/functions/effect/0408.fueling/tick/countdown.mcfunction b/Asset/data/asset/functions/effect/0408.fueling/tick/countdown.mcfunction
new file mode 100644
index 0000000000..96f9bb5ab8
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0408.fueling/tick/countdown.mcfunction
@@ -0,0 +1,11 @@
+#> asset:effect/0408.fueling/tick/countdown
+#
+#
+#
+# @within function asset:effect/0408.fueling/tick/
+
+# Intervalを20にリセット
+    data modify storage asset:context this.Interval set value 20
+
+# 演出
+    playsound block.note_block.bit player @s ~ ~ ~ 1.0 1.0
diff --git a/Asset/data/asset/tags/functions/artifact/click.carrot_on_a_stick.json b/Asset/data/asset/tags/functions/artifact/click.carrot_on_a_stick.json
index 5586d3767c..d5f91d9531 100644
--- a/Asset/data/asset/tags/functions/artifact/click.carrot_on_a_stick.json
+++ b/Asset/data/asset/tags/functions/artifact/click.carrot_on_a_stick.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1643.jet_booster/trigger/1.trigger",
         "asset:artifact/1555.shift_change/trigger/1.trigger",
         "asset:artifact/1636.mana_controller/trigger/1.trigger",
         "asset:artifact/1606.dimension_knife/click/1.trigger",
@@ -180,4 +181,4 @@
         "asset:artifact/2001.staff_of_the_willless/trigger/1.trigger",
         "asset:artifact/0019.scripture/trigger/1.trigger"
     ]
-}
+}
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/artifact/give.json b/Asset/data/asset/tags/functions/artifact/give.json
index 3f770e5a44..bdd3163df2 100644
--- a/Asset/data/asset/tags/functions/artifact/give.json
+++ b/Asset/data/asset/tags/functions/artifact/give.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1643.jet_booster/give/1.trigger",
         "asset:artifact/1392.yellow_refraction_prism/give/1.trigger",
         "asset:artifact/1421.toaster/give/1.trigger",
         "asset:artifact/1555.shift_change/give/1.trigger",
@@ -559,4 +560,4 @@
         "asset:artifact/0735.collision_plate/give/1.trigger",
         "asset:artifact/0745.blade_of_whirlwind/give/1.trigger"
     ]
-}
+}
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/artifact/register.json b/Asset/data/asset/tags/functions/artifact/register.json
index fb738d0354..ff89025623 100644
--- a/Asset/data/asset/tags/functions/artifact/register.json
+++ b/Asset/data/asset/tags/functions/artifact/register.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1643.jet_booster/register",
         "asset:artifact/1421.toaster/register",
         "asset:artifact/1555.shift_change/register",
         "asset:artifact/1466.insulator_helmet/register",
@@ -330,4 +331,4 @@
         "asset:artifact/1027.fire_of_rebirth/register",
         "asset:artifact/1111.rod_o_redeem/register"
     ]
-}
+}
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/effect/end.json b/Asset/data/asset/tags/functions/effect/end.json
index 328f6768d2..3ca7f7f5f4 100644
--- a/Asset/data/asset/tags/functions/effect/end.json
+++ b/Asset/data/asset/tags/functions/effect/end.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0408.fueling/_/end",
         "asset:effect/0359.time_ticker_eclipse/_/end",
         "asset:effect/0358.time_ticker_night/_/end",
         "asset:effect/0357.time_ticker_day/_/end",
@@ -117,4 +118,4 @@
         "asset:effect/0007.defense_base_debuff/_/end",
         "asset:effect/0258.spirit_melody/_/end"
     ]
-}
+}
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/effect/given.json b/Asset/data/asset/tags/functions/effect/given.json
index 90e2aa1f7d..fa9ed137d5 100644
--- a/Asset/data/asset/tags/functions/effect/given.json
+++ b/Asset/data/asset/tags/functions/effect/given.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0408.fueling/_/given",
         "asset:effect/0359.time_ticker_eclipse/_/given",
         "asset:effect/0358.time_ticker_night/_/given",
         "asset:effect/0357.time_ticker_day/_/given",
@@ -112,4 +113,4 @@
         "asset:effect/0007.defense_base_debuff/_/given",
         "asset:effect/0258.spirit_melody/_/given"
     ]
-}
+}
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/effect/register.json b/Asset/data/asset/tags/functions/effect/register.json
index 562930996b..cb3231a398 100644
--- a/Asset/data/asset/tags/functions/effect/register.json
+++ b/Asset/data/asset/tags/functions/effect/register.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0408.fueling/_/register",
         "asset:effect/0359.time_ticker_eclipse/_/register",
         "asset:effect/0358.time_ticker_night/_/register",
         "asset:effect/0357.time_ticker_day/_/register",
@@ -194,4 +195,4 @@
         "asset:effect/0007.defense_base_debuff/_/register",
         "asset:effect/0258.spirit_melody/_/register"
     ]
-}
+}
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/effect/tick.json b/Asset/data/asset/tags/functions/effect/tick.json
index 910ccfd5f6..a81696f439 100644
--- a/Asset/data/asset/tags/functions/effect/tick.json
+++ b/Asset/data/asset/tags/functions/effect/tick.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0408.fueling/_/tick",
         "asset:effect/0359.time_ticker_eclipse/_/tick",
         "asset:effect/0358.time_ticker_night/_/tick",
         "asset:effect/0357.time_ticker_day/_/tick",
@@ -113,4 +114,4 @@
         "asset:effect/0279.poison_of_vinderre/_/tick",
         "asset:effect/0258.spirit_melody/_/tick"
     ]
-}
+}
\ No newline at end of file