diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/dis_equip/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/dis_equip/1.trigger.mcfunction
new file mode 100644
index 0000000000..84f498a83a
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/dis_equip/1.trigger.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1465.versatile_plasma/dis_equip/1.trigger
+#
+# 装備を外した時に外した部位にのみのidが入った状態でトリガーされる
+#
+# @within tag/function asset:artifact/dis_equip
+
+execute if data storage asset:context id{mainhand:1465} run function asset:artifact/1465.versatile_plasma/dis_equip/2.main
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/dis_equip/2.main.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/dis_equip/2.main.mcfunction
new file mode 100644
index 0000000000..9a9a35bf09
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/dis_equip/2.main.mcfunction
@@ -0,0 +1,10 @@
+#> asset:artifact/1465.versatile_plasma/dis_equip/2.main
+#
+# 装備を外した時のメイン処理
+#
+# @within function asset:artifact/1465.versatile_plasma/dis_equip/*
+
+# Effect374を削除
+    data modify storage api: Argument.ID set value 374
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/give/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/give/1.trigger.mcfunction
new file mode 100644
index 0000000000..cc46a1a9a5
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/give/1.trigger.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1465.versatile_plasma/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1465} run function asset:artifact/1465.versatile_plasma/give/2.give
\ No newline at end of file
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/give/2.give.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/give/2.give.mcfunction
new file mode 100644
index 0000000000..fe02979865
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/give/2.give.mcfunction
@@ -0,0 +1,68 @@
+#> asset:artifact/1465.versatile_plasma/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1465.versatile_plasma/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1465
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:ender_eye"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text": "ヴァースティル・プラズマ", "color": "#D4FFBA"}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text": "チャージ段階に応じて異なる方法で攻撃する。"}', '{"text": "1段：短射程の小さい弾を、幅広めにばらまく"}', '{"text": "2段：三方位に、ノックバックするビームを撃つ"}', '{"text": "3段：貫通ビームを撃つ"}', '{"text": "チャージを2層重ねると25、3層重ねると追加で35のMPを消費する。"}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "releaseUsingItem"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value "30 / 150 / 300"
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Physical]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Thunder]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "condition"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackRange set value "???"
+# MP消費量 (int)
+    # data modify storage asset:artifact MPCost set value
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    data modify storage asset:artifact MPHealWhenHit set value 5
+# 神器のクールダウン (int) (オプション)
+    data modify storage asset:artifact LocalCooldown set value 100
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact TypeCooldown.Type set value "longRange"
+    data modify storage asset:artifact TypeCooldown.Duration set value 50
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Urban", "Wi-ki"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/register.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/register.mcfunction
new file mode 100644
index 0000000000..8feac74d30
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/register.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1465.versatile_plasma/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[3] append value [1465]
+data modify storage asset:artifact RarityRegistryWithColor.Red[3] append value [1465]
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/1.trigger.mcfunction
new file mode 100644
index 0000000000..104e94d36b
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/1.trigger.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/1.trigger
+#
+#
+#
+# @within tag/function asset:artifact/using_item/release/
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1465} run function asset:artifact/1465.versatile_plasma/release_using_item/2.check_condition
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/2.check_condition.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/2.check_condition.mcfunction
new file mode 100644
index 0000000000..603ee26b8c
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/2.check_condition.mcfunction
@@ -0,0 +1,18 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/2.check_condition
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/1.trigger
+
+# チャージ時間で攻撃を分ける
+    data modify storage api: Argument.ID set value 374
+    function api:entity/mob/effect/get/from_id
+
+    execute if data storage api: Return.Effect{Stack:1} run function asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/
+    execute if data storage api: Return.Effect{Stack:2} anchored eyes positioned ^ ^-0.25 ^ run function asset:artifact/1465.versatile_plasma/release_using_item/3.2.beam/
+    execute if data storage api: Return.Effect{Stack:3} run function asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/
+
+# Effect374を削除
+    data modify storage api: Argument.ID set value 374
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/.mcfunction
new file mode 100644
index 0000000000..1a9e1bb9b6
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/.mcfunction
@@ -0,0 +1,24 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/2.check_condition
+
+#> Private
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/*
+    #declare score_holder $A1465.Rec
+
+# 36回実行
+    scoreboard players set $A1465.Rec Temporary 36
+
+# 初回だけOffsetが固定
+    data modify storage asset:temp Args.OffsetX set value 0
+    data modify storage asset:temp Args.OffsetY set value 0
+    data modify storage asset:temp Args.OffsetZ set value 2.5
+
+# 再帰
+    execute anchored eyes positioned ^ ^ ^ run function asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/rec
+
+# リセット
+    scoreboard players reset $A1465.Rec
+    data remove storage asset:temp Args
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/rec.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/rec.mcfunction
new file mode 100644
index 0000000000..ee460931de
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/rec.mcfunction
@@ -0,0 +1,19 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/rec
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/*
+
+# rec減算
+    scoreboard players remove $A1465.Rec Temporary 1
+
+# マクロでObject召喚
+    function asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/summon.m with storage asset:temp Args
+
+# ランダムなoffsetを設定
+    execute store result storage asset:temp Args.OffsetX float 0.1 run random value -20..20
+    execute store result storage asset:temp Args.OffsetY float 0.1 run random value -5..5
+    execute store result storage asset:temp Args.OffsetZ float 0.1 run random value 5..35
+
+# 再帰
+    execute if score $A1465.Rec Temporary matches 1.. run function asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/rec
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/summon.m.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/summon.m.mcfunction
new file mode 100644
index 0000000000..46888443a6
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.1.spark/summon.m.mcfunction
@@ -0,0 +1,18 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/summon.m
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/3.1.spark/rec
+
+    data modify storage api: Argument.ID set value 1168
+    # 攻撃情報
+        data modify storage api: Argument.FieldOverride.Damage set value 30
+        data modify storage api: Argument.FieldOverride.AdditionalMPHeal set value 5
+        data modify storage api: Argument.FieldOverride.AttackType set value "Physical"
+        data modify storage api: Argument.FieldOverride.ElementType set value "Thunder"
+
+    # 存在時間
+        execute store result storage api: Argument.FieldOverride.Tick int 1 run random value 2..7
+
+    execute store result storage api: Argument.FieldOverride.UserID int 1 run scoreboard players get @s UserID
+    $execute positioned ^$(OffsetX) ^$(OffsetY) ^$(OffsetZ) run function api:object/summon
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.2.beam/.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.2.beam/.mcfunction
new file mode 100644
index 0000000000..a19fe8a3dc
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.2.beam/.mcfunction
@@ -0,0 +1,15 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.2.beam/
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/2.check_condition
+
+# 3発撃つ
+    execute rotated ~-30 ~ run function asset:artifact/1465.versatile_plasma/release_using_item/3.2.beam/summon
+
+    execute rotated ~ ~ run function asset:artifact/1465.versatile_plasma/release_using_item/3.2.beam/summon
+
+    execute rotated ~30 ~ run function asset:artifact/1465.versatile_plasma/release_using_item/3.2.beam/summon
+
+# 演出
+    playsound block.respawn_anchor.deplete player @a ~ ~ ~ 2 2
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.2.beam/summon.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.2.beam/summon.mcfunction
new file mode 100644
index 0000000000..fa429ed75e
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.2.beam/summon.mcfunction
@@ -0,0 +1,20 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.2.beam/summon
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/3.2.beam/
+
+    data modify storage api: Argument.ID set value 1169
+
+    # 攻撃情報
+        data modify storage api: Argument.FieldOverride.Damage set value 150
+        data modify storage api: Argument.FieldOverride.AdditionalMPHeal set value 5
+        data modify storage api: Argument.FieldOverride.AttackType set value "Physical"
+        data modify storage api: Argument.FieldOverride.ElementType set value "Thunder"
+
+    # 発射体のField
+        data modify storage api: Argument.FieldOverride.Speed set value 2
+        data modify storage api: Argument.FieldOverride.Range set value 50
+
+    execute store result storage api: Argument.FieldOverride.UserID int 1 run scoreboard players get @s UserID
+    function api:object/summon
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/.mcfunction
new file mode 100644
index 0000000000..144a2d893f
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/.mcfunction
@@ -0,0 +1,19 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/2.check_condition
+
+#> Private
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/**
+    #declare tag A1465.Hit
+    #declare tag A1465.HitTarget
+
+# 再帰処理
+    execute anchored eyes positioned ^ ^ ^ run function asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/rec
+    tag @s remove A1465.Hit
+    function asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/damage
+
+# 演出
+    playsound ogg:block.vault.open_shutter player @a ~ ~ ~ 2 2
+    playsound ogg:block.vault.break player @a ~ ~ ~ 1 1
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/damage.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/damage.mcfunction
new file mode 100644
index 0000000000..4203a76b28
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/damage.mcfunction
@@ -0,0 +1,17 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/damage
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/
+
+# ダメージ
+    data modify storage api: Argument.Damage set value 300
+    data modify storage api: Argument.AdditionalMPHeal set value 5
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Thunder"
+    function api:damage/modifier
+    execute as @e[type=#lib:living_without_player,tag=A1465.HitTarget,distance=..20] run function api:damage/
+    function api:damage/reset
+
+# A1465.HitTargetタグ削除
+    tag @e[type=#lib:living_without_player,tag=A1465.HitTarget,distance=..20] remove A1465.HitTarget
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/rec.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/rec.mcfunction
new file mode 100644
index 0000000000..6384adee4c
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/release_using_item/3.3.laser/rec.mcfunction
@@ -0,0 +1,19 @@
+#> asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/rec
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/*
+
+# 着弾検知
+    execute unless block ^ ^ ^0.5 #lib:no_collision/ run tag @s add A1465.Hit
+
+# 命中
+    execute positioned ~-0.5 ~-0.5 ~-0.5 run tag @e[type=#lib:living_without_player,tag=Enemy,tag=!A1465.HitTarget,tag=!Uninterferable,dx=0,limit=1] add A1465.HitTarget
+
+# 演出
+    particle dust 0.8 1.0 0.5 1.0 ~ ~ ~ 0.0 0.0 0.0 1 1
+    particle dust 0.5 1.0 0.5 1.5 ~ ~ ~ 0.0 0.0 0.0 1 1
+    particle dust 0.8 0.8 0.3 0.5 ~ ~ ~ 0.0 0.0 0.0 1 1
+
+# 再帰
+    execute positioned ^ ^ ^0.5 if entity @s[tag=!A1465.Hit,distance=..20] run function asset:artifact/1465.versatile_plasma/release_using_item/3.3.laser/rec
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/1.trigger.mcfunction
new file mode 100644
index 0000000000..1ec0fc6d1f
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/1.trigger.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1465.versatile_plasma/using_item/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1465} run function asset:artifact/1465.versatile_plasma/using_item/2.check_condition
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/2.check_condition.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/2.check_condition.mcfunction
new file mode 100644
index 0000000000..76bb141eb7
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/2.check_condition.mcfunction
@@ -0,0 +1,17 @@
+#> asset:artifact/1465.versatile_plasma/using_item/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1465.versatile_plasma/using_item/1.trigger
+
+# チャージ段階のEffect取得
+    data modify storage api: Argument.ID set value 374
+    function api:entity/mob/effect/get/from_id
+# チャージ中ならば強制的にチャージ続行
+    execute if data storage api: Return.Effect run return run function asset:artifact/1465.versatile_plasma/using_item/charge
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1465.versatile_plasma/using_item/3.main
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/3.main.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/3.main.mcfunction
new file mode 100644
index 0000000000..a05cb0d113
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/3.main.mcfunction
@@ -0,0 +1,16 @@
+#> asset:artifact/1465.versatile_plasma/using_item/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1465.versatile_plasma/using_item/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# チャージ用Effectを付与
+    data modify storage api: Argument.ID set value 374
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# 演出
+    playsound block.iron_door.open player @a ~ ~ ~ 2 0.5
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge.mcfunction
new file mode 100644
index 0000000000..0a43978661
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge.mcfunction
@@ -0,0 +1,9 @@
+#> asset:artifact/1465.versatile_plasma/using_item/charge
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/using_item/2.check_condition
+
+# 長押しした時間からEffect374のスタックを更新
+    execute if data storage asset:context UsingItemTime{mainhand:25} run function asset:artifact/1465.versatile_plasma/using_item/charge/check/2
+    execute if data storage asset:context UsingItemTime{mainhand:50} run function asset:artifact/1465.versatile_plasma/using_item/charge/check/3
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/2.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/2.mcfunction
new file mode 100644
index 0000000000..7d7bbb90d1
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/2.mcfunction
@@ -0,0 +1,22 @@
+#> asset:artifact/1465.versatile_plasma/using_item/charge/2
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/using_item/charge/**
+
+# スタック数を増やす
+    data modify storage api: Argument.ID set value 374
+    data modify storage api: Argument.Stack set value 2
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# MP消費
+    data modify storage api: Argument.Fluctuation set value -25
+    data modify storage api: Argument.DisableLog set value 1b
+    function api:mp/fluctuation
+
+# 演出
+    playsound block.piston.extend player @a ~ ~ ~ 2 2
+    particle dust 0.8 1.0 0.5 2.0 ~ ~ ~ 0.5 1.0 0.5 1 8
+    particle dust 0.5 1.0 0.5 2.5 ~ ~ ~ 0.5 1.0 0.5 1 8
+    particle dust 0.8 0.8 0.3 1.5 ~ ~ ~ 0.5 1.0 0.5 1 8
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/3.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/3.mcfunction
new file mode 100644
index 0000000000..4f1dc742ee
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/3.mcfunction
@@ -0,0 +1,23 @@
+#> asset:artifact/1465.versatile_plasma/using_item/charge/3
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/using_item/charge/**
+
+# スタック数を増やす
+    data modify storage api: Argument.ID set value 374
+    data modify storage api: Argument.Stack set value 3
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset
+
+# MP消費
+    data modify storage api: Argument.Fluctuation set value -35
+    data modify storage api: Argument.DisableLog set value 1b
+    function api:mp/fluctuation
+
+# 演出
+    playsound block.piston.extend player @a ~ ~ ~ 2 2
+    playsound block.trial_spawner.detect_player player @a ~ ~ ~ 2 0.5
+    particle dust 0.8 1.0 0.5 2.0 ~ ~ ~ 0.5 1.0 0.5 1 8
+    particle dust 0.5 1.0 0.5 2.5 ~ ~ ~ 0.5 1.0 0.5 1 8
+    particle dust 0.8 0.8 0.3 1.5 ~ ~ ~ 0.5 1.0 0.5 1 8
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/check/2.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/check/2.mcfunction
new file mode 100644
index 0000000000..b80cf31d75
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/check/2.mcfunction
@@ -0,0 +1,10 @@
+#> asset:artifact/1465.versatile_plasma/using_item/charge/check/2
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/using_item/charge
+
+# MPが一定値以上なら攻撃
+    data modify storage api: Argument.Threshold set value 25
+    function api:mp/check
+    execute if data storage api: Return{IsThresholdOrMore:true} run function asset:artifact/1465.versatile_plasma/using_item/charge/2
diff --git a/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/check/3.mcfunction b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/check/3.mcfunction
new file mode 100644
index 0000000000..ee636082e1
--- /dev/null
+++ b/Asset/data/asset/functions/artifact/1465.versatile_plasma/using_item/charge/check/3.mcfunction
@@ -0,0 +1,10 @@
+#> asset:artifact/1465.versatile_plasma/using_item/charge/check/3
+#
+#
+#
+# @within function asset:artifact/1465.versatile_plasma/using_item/charge
+
+# MPが一定値以上なら攻撃
+    data modify storage api: Argument.Threshold set value 35
+    function api:mp/check
+    execute if data storage api: Return{IsThresholdOrMore:true} run function asset:artifact/1465.versatile_plasma/using_item/charge/3
diff --git a/Asset/data/asset/functions/effect/0374.charge_plasma/_/register.mcfunction b/Asset/data/asset/functions/effect/0374.charge_plasma/_/register.mcfunction
new file mode 100644
index 0000000000..97b034bcbd
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0374.charge_plasma/_/register.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0374.charge_plasma/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:374} run function asset:effect/0374.charge_plasma/register
diff --git a/Asset/data/asset/functions/effect/0374.charge_plasma/register.mcfunction b/Asset/data/asset/functions/effect/0374.charge_plasma/register.mcfunction
new file mode 100644
index 0000000000..1020e267e2
--- /dev/null
+++ b/Asset/data/asset/functions/effect/0374.charge_plasma/register.mcfunction
@@ -0,0 +1,38 @@
+#> asset:effect/0374.charge_plasma/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0374.charge_plasma/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 374
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text": "チャージ・プラズマ", "color": "#D4FFBA"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value ['{"text": "チャージ終了時、チャージ段階に応じて異なる攻撃を放つ"}']
+# 効果時間 (int) (default = API || error)
+    data modify storage asset:effect Duration set value 2147483647
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value
+# 効果時間の操作方法 (default = API || "replace")
+    # data modify storage asset:effect DurationOperation set value
+# スタックの操作方法 (default = API || "replace")
+    # data modify storage asset:effect StackOperation set value
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value
+# 最大スタック (int) (default = 2147483647)
+    data modify storage asset:effect MaxStack set value 3
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value false
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 3
+# エフェクトをUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect Visible set value
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect StackVisible set value
+
+# フィールド
diff --git a/Asset/data/asset/functions/object/1168.plasma_spark/init/.mcfunction b/Asset/data/asset/functions/object/1168.plasma_spark/init/.mcfunction
new file mode 100644
index 0000000000..a605136d16
--- /dev/null
+++ b/Asset/data/asset/functions/object/1168.plasma_spark/init/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/1168.plasma_spark/init/
+#
+# Objectのinit時の処理
+#
+# @within asset:object/alias/1168/init
+
+# Tickをランダムに設定
+    execute store result score @s General.Object.Tick run data get storage asset:context this.Tick
diff --git a/Asset/data/asset/functions/object/1168.plasma_spark/register.mcfunction b/Asset/data/asset/functions/object/1168.plasma_spark/register.mcfunction
new file mode 100644
index 0000000000..290754a97c
--- /dev/null
+++ b/Asset/data/asset/functions/object/1168.plasma_spark/register.mcfunction
@@ -0,0 +1,23 @@
+#> asset:object/1168.plasma_spark/register
+#
+# Objectのデータを指定
+#
+# @within function asset:object/alias/1168/register
+
+# 継承(オプション)
+    # data modify storage asset:object Extends append value
+    # function asset:object/extends
+# 他のObjectに継承されることを許可するか (boolean) (オプション)
+    # data modify storage asset:object ExtendsSafe set value
+# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
+    data modify storage asset:object IsAbstract set value false
+# Tickするかどうか(boolean) (オプション)
+    # data modify storage asset:object IsTicking set value
+
+# ID (int)
+    data modify storage asset:object ID set value 1168
+# フィールド(オプション)
+    data modify storage asset:object Field.Damage set value 0
+    data modify storage asset:object Field.AdditionalMPHeal set value 0
+    data modify storage asset:object Field.Tick set value 0
+    data modify storage asset:object Field.UserID set value -1
diff --git a/Asset/data/asset/functions/object/1168.plasma_spark/summon/.mcfunction b/Asset/data/asset/functions/object/1168.plasma_spark/summon/.mcfunction
new file mode 100644
index 0000000000..2f2d174a7d
--- /dev/null
+++ b/Asset/data/asset/functions/object/1168.plasma_spark/summon/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/1168.plasma_spark/summon/
+#
+# Object召喚処理の呼び出し時に実行されるfunction
+#
+# @within asset:object/alias/1168/summon
+
+# 元となるEntityを召喚する
+    summon marker ~ ~ ~ {Tags:["ObjectInit"]}
diff --git a/Asset/data/asset/functions/object/1168.plasma_spark/summon/debug.mcfunction b/Asset/data/asset/functions/object/1168.plasma_spark/summon/debug.mcfunction
new file mode 100644
index 0000000000..9423b8a200
--- /dev/null
+++ b/Asset/data/asset/functions/object/1168.plasma_spark/summon/debug.mcfunction
@@ -0,0 +1,10 @@
+#> asset:object/1168.plasma_spark/summon/debug
+#
+# 動作チェック用の召喚処理 使い終わったら消してもいいかも
+#
+# @user
+# @private
+
+# 召喚
+    data modify storage api: Argument.ID set value 1168
+    function api:object/summon
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/1168.plasma_spark/tick/.mcfunction b/Asset/data/asset/functions/object/1168.plasma_spark/tick/.mcfunction
new file mode 100644
index 0000000000..7f6341f01c
--- /dev/null
+++ b/Asset/data/asset/functions/object/1168.plasma_spark/tick/.mcfunction
@@ -0,0 +1,11 @@
+#> asset:object/1168.plasma_spark/tick/
+#
+# Objectのtick時の処理
+#
+# @within asset:object/alias/1168/tick
+
+# Tick減算
+    scoreboard players remove @s General.Object.Tick 1
+
+# 炸裂処理
+    execute if score @s General.Object.Tick matches ..0 run function asset:object/1168.plasma_spark/tick/explode
diff --git a/Asset/data/asset/functions/object/1168.plasma_spark/tick/explode.mcfunction b/Asset/data/asset/functions/object/1168.plasma_spark/tick/explode.mcfunction
new file mode 100644
index 0000000000..b257cc0b33
--- /dev/null
+++ b/Asset/data/asset/functions/object/1168.plasma_spark/tick/explode.mcfunction
@@ -0,0 +1,30 @@
+#> asset:object/1168.plasma_spark/tick/explode
+#
+# 攻撃処理
+#
+# @within function asset:object/1168.plasma_spark/tick/**
+
+#> Private
+# @private
+    #declare score_holder $O1168.UserID
+
+# 攻撃判定
+    data modify storage api: Argument.Damage set from storage asset:context this.Damage
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Thunder"
+    data modify storage api: Argument.AdditionalMPHeal set from storage asset:context this.AdditionalMPHeal
+    execute store result score $O1168.UserID Temporary run data get storage asset:context this.UserID
+    execute as @a if score @s UserID = $O1168.UserID Temporary run function api:damage/modifier
+    execute positioned ~-0.125 ~-0.125 ~-0.125 as @e[type=#lib:living_without_player,tag=Enemy,tag=!Uninterferable,dx=0] positioned ~-0.75 ~-0.75 ~-0.75 if entity @s[dx=0] run function api:damage/
+    function api:damage/reset
+
+# 演出
+    particle end_rod ~ ~ ~ 0 0 0 0 1
+    playsound entity.firework_rocket.twinkle player @a ~ ~ ~ 0.25 2
+    playsound block.copper_bulb.turn_on player @a ~ ~ ~ 2 2
+
+# リセット
+    scoreboard players reset $O1168.UserID
+
+# 消す
+    kill @s
diff --git a/Asset/data/asset/functions/object/1169.plasma_beam/detect_hit_entity/.mcfunction b/Asset/data/asset/functions/object/1169.plasma_beam/detect_hit_entity/.mcfunction
new file mode 100644
index 0000000000..1cd28860ac
--- /dev/null
+++ b/Asset/data/asset/functions/object/1169.plasma_beam/detect_hit_entity/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/1169.plasma_beam/detect_hit_entity/
+#
+# 継承先などから実行される処理
+#
+# @within asset:object/alias/1169/detect_hit_entity
+
+# 判定
+    execute positioned ~-0.5 ~-0.5 ~-0.5 if entity @e[type=#lib:living_without_player,tag=Enemy,tag=!Uninterferable,dx=0] run data modify storage asset:context IsHitEntity set value true
diff --git a/Asset/data/asset/functions/object/1169.plasma_beam/hit_entity/.mcfunction b/Asset/data/asset/functions/object/1169.plasma_beam/hit_entity/.mcfunction
new file mode 100644
index 0000000000..7eb4703125
--- /dev/null
+++ b/Asset/data/asset/functions/object/1169.plasma_beam/hit_entity/.mcfunction
@@ -0,0 +1,11 @@
+#> asset:object/1169.plasma_beam/hit_entity/
+#
+# ヒット処理
+#
+# @within asset:object/alias/1169/hit_entity
+
+# ダメージ
+    execute positioned ~-0.5 ~-0.5 ~-0.5 as @e[type=#lib:living_without_player,tag=Enemy,tag=!Uninterferable,dx=0,sort=random,limit=1] run function asset:object/1169.plasma_beam/hit_entity/damage
+
+# 消す
+    function asset:object/call.m {method:kill}
diff --git a/Asset/data/asset/functions/object/1169.plasma_beam/hit_entity/damage.mcfunction b/Asset/data/asset/functions/object/1169.plasma_beam/hit_entity/damage.mcfunction
new file mode 100644
index 0000000000..dcb5020960
--- /dev/null
+++ b/Asset/data/asset/functions/object/1169.plasma_beam/hit_entity/damage.mcfunction
@@ -0,0 +1,26 @@
+#> asset:object/1169.plasma_beam/hit_entity/damage
+#
+# ダメージ処理
+#
+# @within function asset:object/1169.plasma_beam/hit_entity/
+
+#> Private
+# @private
+    #declare score_holder $O1169.UserID
+
+    data modify storage api: Argument.Damage set from storage asset:context this.Damage
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Thunder"
+    data modify storage api: Argument.AdditionalMPHeal set from storage asset:context this.AdditionalMPHeal
+    execute store result score $O1169.UserID Temporary run data get storage asset:context this.UserID
+    execute as @a if score @s UserID = $O1169.UserID Temporary run function api:damage/modifier
+    function api:damage/
+    function api:damage/reset
+
+# ノックバック
+    data modify storage lib: Argument.KnockbackResist set value true
+    data modify storage lib: Argument.VectorMagnitude set value 3.5d
+    execute rotated ~ -30 run function lib:motion/looking
+
+# リセット
+    scoreboard players reset $O1169.UserID
diff --git a/Asset/data/asset/functions/object/1169.plasma_beam/register.mcfunction b/Asset/data/asset/functions/object/1169.plasma_beam/register.mcfunction
new file mode 100644
index 0000000000..61eb683ef1
--- /dev/null
+++ b/Asset/data/asset/functions/object/1169.plasma_beam/register.mcfunction
@@ -0,0 +1,25 @@
+#> asset:object/1169.plasma_beam/register
+#
+# Objectのデータを指定
+#
+# @within function asset:object/alias/1169/register
+
+# 継承(オプション)
+    data modify storage asset:object Extends append value 1
+    function asset:object/extends
+# 他のObjectに継承されることを許可するか (boolean) (オプション)
+    # data modify storage asset:object ExtendsSafe set value
+# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
+    data modify storage asset:object IsAbstract set value false
+# Tickするかどうか(boolean) (オプション)
+    data modify storage asset:object IsTicking set value true
+
+# ID (int)
+    data modify storage asset:object ID set value 1169
+# フィールド(オプション)
+    data modify storage asset:object Field.Damage set value 0
+    data modify storage asset:object Field.AdditionalMPHeal set value 0
+    data modify storage asset:object Field.UserID set value -1
+
+    data modify storage asset:object Field.Speed set value 0
+    data modify storage asset:object Field.Range set value 0
diff --git a/Asset/data/asset/functions/object/1169.plasma_beam/summon/.mcfunction b/Asset/data/asset/functions/object/1169.plasma_beam/summon/.mcfunction
new file mode 100644
index 0000000000..959010ef5d
--- /dev/null
+++ b/Asset/data/asset/functions/object/1169.plasma_beam/summon/.mcfunction
@@ -0,0 +1,11 @@
+#> asset:object/1169.plasma_beam/summon/
+#
+# Object召喚処理の呼び出し時に実行されるfunction
+#
+# @within asset:object/alias/1169/summon
+
+# 元となるEntityを召喚する
+    execute as 0-0-0-0-0 in minecraft:overworld positioned as @s run tp @s ^ ^ ^ ~ ~
+    data modify storage asset:temp Args.Rotation set from entity 0-0-0-0-0 Rotation
+    function asset:object/1169.plasma_beam/summon/m with storage asset:temp Args
+    data remove storage asset:temp Args
diff --git a/Asset/data/asset/functions/object/1169.plasma_beam/summon/debug.mcfunction b/Asset/data/asset/functions/object/1169.plasma_beam/summon/debug.mcfunction
new file mode 100644
index 0000000000..80568122ea
--- /dev/null
+++ b/Asset/data/asset/functions/object/1169.plasma_beam/summon/debug.mcfunction
@@ -0,0 +1,10 @@
+#> asset:object/1169.plasma_beam/summon/debug
+#
+# 動作チェック用の召喚処理 使い終わったら消してもいいかも
+#
+# @user
+# @private
+
+# 召喚
+    data modify storage api: Argument.ID set value 1169
+    function api:object/summon
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/1169.plasma_beam/summon/m.mcfunction b/Asset/data/asset/functions/object/1169.plasma_beam/summon/m.mcfunction
new file mode 100644
index 0000000000..5364d165be
--- /dev/null
+++ b/Asset/data/asset/functions/object/1169.plasma_beam/summon/m.mcfunction
@@ -0,0 +1,7 @@
+#> asset:object/1169.plasma_beam/summon/m
+#
+# @input args:
+#   Rotation : float @ 2
+# @within function asset:object/1169.plasma_beam/summon/
+
+    $summon item_display ~ ~ ~ {Rotation: $(Rotation),Tags:["ObjectInit"],item:{id:"minecraft:stick",Count:1b,tag:{CustomModelData:20630}},brightness:{block:15,sky:15},teleport_duration:1}
diff --git a/Asset/data/asset/functions/object/alias/1168/init.mcfunction b/Asset/data/asset/functions/object/alias/1168/init.mcfunction
new file mode 100644
index 0000000000..a0a41b7315
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1168/init.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1168/init
+#
+# Init処理のエイリアス
+#
+# @within asset_manager:object/init/init.m
+
+# 元のInit処理を呼び出す
+    function asset:object/1168.plasma_spark/init/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/alias/1168/register.mcfunction b/Asset/data/asset/functions/object/alias/1168/register.mcfunction
new file mode 100644
index 0000000000..81771735e3
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1168/register.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1168/register
+#
+# Objectのデータ指定処理のエイリアス
+#
+# @within asset_manager:object/summon/register.m
+
+# 元の登録処理を呼び出す
+    function asset:object/1168.plasma_spark/register
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/alias/1168/summon.mcfunction b/Asset/data/asset/functions/object/alias/1168/summon.mcfunction
new file mode 100644
index 0000000000..461e2deec8
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1168/summon.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1168/summon
+#
+# Object召喚処理のエイリアス
+#
+# @within asset_manager:object/summon/summon.m
+
+# 元の召喚処理を呼び出す
+    function asset:object/1168.plasma_spark/summon/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/alias/1168/tick.mcfunction b/Asset/data/asset/functions/object/alias/1168/tick.mcfunction
new file mode 100644
index 0000000000..b7822787b3
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1168/tick.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1168/tick
+#
+# Tick時処理のエイリアス
+#
+# @within asset_manager:object/tick/tick.m
+
+# 元のTick処理を呼び出す
+    function asset:object/1168.plasma_spark/tick/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/alias/1169/detect_hit_entity.mcfunction b/Asset/data/asset/functions/object/alias/1169/detect_hit_entity.mcfunction
new file mode 100644
index 0000000000..aaf4cb2a3d
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1169/detect_hit_entity.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1169/detect_hit_entity
+#
+# メソッド処理のエイリアス
+#
+# @within asset_manager:object/call_method/run_method.m
+
+# 元のメソッド処理を呼び出す
+    function asset:object/1169.plasma_beam/detect_hit_entity/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/alias/1169/hit_entity.mcfunction b/Asset/data/asset/functions/object/alias/1169/hit_entity.mcfunction
new file mode 100644
index 0000000000..301f4e7e96
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1169/hit_entity.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1169/hit_entity
+#
+# メソッド処理のエイリアス
+#
+# @within asset_manager:object/call_method/run_method.m
+
+# 元のメソッド処理を呼び出す
+    function asset:object/1169.plasma_beam/hit_entity/
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/alias/1169/register.mcfunction b/Asset/data/asset/functions/object/alias/1169/register.mcfunction
new file mode 100644
index 0000000000..e8cc16b447
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1169/register.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1169/register
+#
+# Objectのデータ指定処理のエイリアス
+#
+# @within asset_manager:object/summon/register.m
+
+# 元の登録処理を呼び出す
+    function asset:object/1169.plasma_beam/register
\ No newline at end of file
diff --git a/Asset/data/asset/functions/object/alias/1169/summon.mcfunction b/Asset/data/asset/functions/object/alias/1169/summon.mcfunction
new file mode 100644
index 0000000000..798eaeb33d
--- /dev/null
+++ b/Asset/data/asset/functions/object/alias/1169/summon.mcfunction
@@ -0,0 +1,8 @@
+#> asset:object/alias/1169/summon
+#
+# Object召喚処理のエイリアス
+#
+# @within asset_manager:object/summon/summon.m
+
+# 元の召喚処理を呼び出す
+    function asset:object/1169.plasma_beam/summon/
\ No newline at end of file
diff --git a/Asset/data/asset/tags/functions/artifact/dis_equip.json b/Asset/data/asset/tags/functions/artifact/dis_equip.json
index 5566bef391..0694c6873f 100644
--- a/Asset/data/asset/tags/functions/artifact/dis_equip.json
+++ b/Asset/data/asset/tags/functions/artifact/dis_equip.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1465.versatile_plasma/dis_equip/1.trigger",
         "asset:artifact/1269.apocalypse/dis_equip/1.trigger",
         "asset:artifact/1615.ema_of_abundance/trigger/dis_equip/",
         "asset:artifact/1606.dimension_knife/dis_equip/1.trigger",
diff --git a/Asset/data/asset/tags/functions/artifact/give.json b/Asset/data/asset/tags/functions/artifact/give.json
index a362a1954c..f2a5506fde 100644
--- a/Asset/data/asset/tags/functions/artifact/give.json
+++ b/Asset/data/asset/tags/functions/artifact/give.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1465.versatile_plasma/give/1.trigger",
         "asset:artifact/1661.starlight_circle/give/1.trigger",
         "asset:artifact/1390.red_refraction_prism/give/1.trigger",
         "asset:artifact/1662.salmon_canon/give/1.trigger",
diff --git a/Asset/data/asset/tags/functions/artifact/register.json b/Asset/data/asset/tags/functions/artifact/register.json
index 26a2324e12..81173db760 100644
--- a/Asset/data/asset/tags/functions/artifact/register.json
+++ b/Asset/data/asset/tags/functions/artifact/register.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1465.versatile_plasma/register",
         "asset:artifact/1661.starlight_circle/register",
         "asset:artifact/1662.salmon_canon/register",
         "asset:artifact/1626.years_magic_index/register",
diff --git a/Asset/data/asset/tags/functions/artifact/using_item/keep/.json b/Asset/data/asset/tags/functions/artifact/using_item/keep/.json
index 5ad644a7dc..473b7fc51f 100644
--- a/Asset/data/asset/tags/functions/artifact/using_item/keep/.json
+++ b/Asset/data/asset/tags/functions/artifact/using_item/keep/.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:artifact/1465.versatile_plasma/using_item/1.trigger",
         "asset:artifact/1421.toaster/trigger/1.trigger",
         "asset:artifact/1637.precise_mana_controller/trigger/1.trigger",
         "asset:artifact/1453.frost_flake_bow/using_item/1.trigger",
diff --git a/Asset/data/asset/tags/functions/artifact/using_item/release/.json b/Asset/data/asset/tags/functions/artifact/using_item/release/.json
index 5c922d2bbf..e9c0195dbd 100644
--- a/Asset/data/asset/tags/functions/artifact/using_item/release/.json
+++ b/Asset/data/asset/tags/functions/artifact/using_item/release/.json
@@ -1,5 +1,5 @@
 {
     "values": [
-
+        "asset:artifact/1465.versatile_plasma/release_using_item/1.trigger"
     ]
 }
diff --git a/Asset/data/asset/tags/functions/effect/register.json b/Asset/data/asset/tags/functions/effect/register.json
index 55a4d503dc..89f82aa639 100644
--- a/Asset/data/asset/tags/functions/effect/register.json
+++ b/Asset/data/asset/tags/functions/effect/register.json
@@ -1,5 +1,6 @@
 {
     "values": [
+        "asset:effect/0374.charge_plasma/_/register",
         "asset:effect/0405.predation_of_tree/_/register",
         "asset:effect/0359.time_ticker_eclipse/_/register",
         "asset:effect/0358.time_ticker_night/_/register",