DFRefactor.src

//****************************************************************************
// $Module type: Program
// $Module name: DFRefactor
// $Author     : Nils Svedmyr, RDC Tools International, <mailto:support@rdctools.com>
// Web-site    : http://www.rdctools.com
// Created     : 2018-08-05 @ 09:50 (Military date format: YY-MM-DD)
//
// Description : Code Refactor functions for DataFlex.
//
// The code is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
// without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
// This is free software; you can redistribute it and/or modify it under the terms of the
// GNU Lesser General Public License - see the "GNU Lesser General Public License.txt"
// in the help folder for more details.
//
//****************************************************************************
Use DFAllEnt.pkg
Use cRDCCJCommandBarSystem.pkg
Use File_dlg.pkg
Use gFormatNumbers.pkg
Use vWin32fh.pkg
Use RefactorConstants.h.pkg
Use cWorkspaceMenuItem.pkg

// Uncomment this define statement to show a "Theme selector" combo-button and
// a "Snap Shot" camera iton in the toolbar.
//Define Is$BlingStuff

// Not sure why we need this, but it somehow is linked to the "OnIdle events"
Procedure Exit_Application for cDesktop
    Send SuspendGUI of Desktop True
    If (Exit_System_Confirmation(Self)) ;
        Abort
End_Procedure

Object oHtmlHelp is a cHtmlHelp
    Set pbAlwaysOnTop to False
End_Object

// Dummy messages that are called from the toolbars; in case they
// doesn't exist in a view. This avoids runtime errors.
Function Can_UndoAction Desktop Returns Boolean
    Function_Return False
End_Function

Function Can_RedoAction Desktop Returns Boolean
    Function_Return False
End_Function

Function pbShouldSave Desktop Returns Boolean
    Function_Return False
End_Function

Function BackupFile Desktop Returns String
    Function_Return ""
End_Function

Procedure OpenSourceFile Desktop
End_Procedure

Procedure Compare Desktop String sCompareApp
End_Procedure

Procedure OnWorkspaceLoaded Desktop
End_Procedure

Procedure LoadFile Desktop String sFileName
End_Procedure

External_Function GetACP "GetACP" kernel32.dll Returns Integer
Register_Procedure DoChangeFontSize

Enum_List
    Define CI_CleanupSource
    Define CI_CodeIndenter
End_Enum_List

// Needs to be _before_ the cApplication object as we refer to it there.
// However, the package itself must be Used _after_ the ghoApplication object,
// as it contains references to the phoWorkspace property. (Kind of catch 22).
Global_Variable Integer ghoEditorProperties
Move 0 to ghoEditorProperties

Declare_Datafile FolderSelHea
Use cFunctionsDataDictionary.dd
Use cRefactorApplication.pkg

Object oApplication is a cRefactorApplication
    Set psProduct to "DFRefactor"
    Set psCompany to "RDC Tools International"
    Set peHelpType to htHtmlHelp
    Set psHelpFile to "DFRefactor.chm"

    Property String[] pasCmdLineSetSelectedFolders 
    Property Boolean pbBatchMode False
    Property String psCmdLineIniFile ""
    
    Procedure OnWorkspaceOpened
        String sProduct
        Integer iRetval
        
        Forward Send OnWorkspaceOpened  
        /* Check that the 'correct' collating.cfg is used when the program is
           started. The data in the database was entered with an english (standard)
           collating sequence. If another df_collate.cfg is encountered at runtime,
           all data tables will automatically be reindexed, prior to running the program.
           Note: We cannot use the event OnCreate for this, because the psDataPath
           et. al. is set after that event.
        */
        Open Functions
        Send CheckCollatingSequence of ghoDatabaseFunctions File_Field Functions.Function_Name
    End_Procedure

    Procedure Set psSWSFile String sSWSFile
        Handle hoCombo
        Integer iItem iCount
        String sListItem
        
        Forward Set psSWSFile to sSWSFile
        If (ghoCommandBars > 0) Begin
            Send DisplayWorkspaceItem of (oWorkspaceSelector_Menuitem(ghoCommandBars)) sSWSFile
            If (hoCombo > 0) Begin
                Get ComListCount of hoCombo to iCount
                For iItem from 0 to iCount
                    Get ComList of hoCombo iItem to sListItem
                    If (sListItem = "Select Workspace:") Begin
                        Set ComListIndex of hoCombo to iItem
                    End
                Loop
                Send Destroy of hoCombo
            End
        End
    End_Procedure
    
    Procedure OnFileNameUpdate String sFileName
        String sText sFileBrowseText sFileNameOnly

        If (sFileName <> "") Begin
            Move sFileName to sText
            Get ParseFileName sFileName to sFileNameOnly
            Move CS_CurrentSourceFileTxt to sFileBrowseText
        End
        Else Begin
            Move CS_BrowseSourceFileTxt to sFileBrowseText
            Move CS_NoActiveSourceFileText to sText
        End

        Set psCurrentSourceFileName to sFileName
        If (phoMainPanel(Self) <> 0) Begin
            Set psCaption of (oOpenFolderMenuItem(ghoCommandBars))      to sFileBrowseText
            Set psCaption of (oSourceFileText_MenuItem(ghoCommandBars)) to sFileNameOnly
            Set psToolTip of (oSourceFileText_MenuItem(ghoCommandBars)) to sText
            Set pbChecked of (oSourceFileText_MenuItem(ghoCommandBars)) to (sText <> "")
        End
    End_Procedure

    Procedure ToggleWorkspaceMode
        Boolean bState
        Get pbWorkspaceMode to bState
        If (oWorkspaceRadio_MenuItem(ghoCommandBars) <> 0) Begin
            Set pbChecked of (oWorkspaceRadio_MenuItem(ghoCommandBars)) to bState
        End
        If (oFileRadioMenuItem(ghoCommandBars) <> 0) Begin
            Set pbChecked of (oFileRadioMenuItem(ghoCommandBars)) to (not(bState))
        End
    End_Procedure

    Procedure SelectSourceFile
        Boolean bOpen bReadOnly bExists
        String  sFileName sHomePath sAppSrcPath sInitialFolder
        Handle ho

        Move (phoOpenSourceFileDialog(Self)) to ho
        Get Initial_Folder of ho to sInitialFolder
        If (sInitialFolder = "") Begin
            Get psHomePath to sHomePath
            // If an "AppSrc" folder exists we want to display those source files.
            Get vFolderFormat sHomePath to sAppSrcPath
            Move (sAppSrcPath + "AppSrc") to sAppSrcPath
            Get vFolderExists sAppSrcPath to bExists
            If (bExists = True) Begin
                Move sAppSrcPath to sHomePath
            End

            Set Initial_Folder of ho to sHomePath
        End
        Get Show_Dialog of ho to bOpen
        If (bOpen = True) Begin
            Get File_Name of ho to sFileName
            // Check if user is opening file as read_only
            Get TickReadOnly_State of ho to bReadOnly
            If (bReadOnly = True) Begin
                Send Info_Box ("Files should not be opened as ReadOnly.") "Warning!"
            End
            Else Begin
                Set pbWorkspaceMode to False
                Send OnFileNameUpdate sFileName
                Send LoadFile of (phoEditor(Self)) sFileName
                Send Activate_oEditorView_vw of (Client_Id(phoMainPanel(Self)))
            End
        End
    End_Procedure

    /* Command Line Interface:
       "/h" "/help" or "/?" - Show command line parameters help
    
      Enables the ability to pass, on the command line;
      - The path and name of a *.sws file
      - And path to a source -folder or -filename
      
      Command line samples:
      /sws "C:\DataFlex 24.0 Examples\Order Entry\Order Entry.sws" /d AppSrc;AppHtml;DDSrc
      /c "C:\DataFlex 24.0 Examples\DFRefactorCmdLineOE.ini"
      
      This command line sample would tell the DFRefactor program to run automatically, 
      applying all previously selected refactoring functions and apply them to all source
      files for the AppSrc, AppHtml and DDSrc folders, that matches the file extensions previously
      setup in the DFRefactor program. Then exit the program when done.   
      Note: The program's UI will be visible while the program runs. However, no UI
            interaction is needed while it is run. All actions as well as possible errors,
            will be automatically registered, but not shown on screen.
    */
    Procedure OnWorkspaceOpened
        Handle hoCmdLine
        String sSourceFile sSWSFile sChar sArgument sParamText sFolders sPath sCmdLineIniFile
        Integer iWin10BetaSetting iNumArgs iCount 
        Boolean bShowParamHelp bDebugMode bBatch bConfigFile
        String[] asFolders
        
        // Test for serious Windows 10 "bug": "https://support.dataaccess.com/Forums/showthread.php?64797-Recent-Microsoft-Changes-to-Windows-10-May-Impact-Functionality-and-or-Data-Integrity"
        Move (GetACP()) to iWin10BetaSetting
        If (iWin10BetaSetting = 65001) Begin
            Send Info_Box ("Windows 10 ouch! This workstation has its BETA option set to TRUE. This means that the normal codepage that DataFlex relies on does not work. This also means that some refactoring functions will fail. Program will now exit!")
            Send vShellExecute "Open" "https://support.dataaccess.com/Forums/showthread.php?64797-Recent-Microsoft-Changes-to-Windows-10-May-Impact-Functionality-and-or-Data-Integrity" "" ""
            Send Exit_Application
        End
        
        Set psStartupProgramPath to (psProgramPath(phoWorkspace(Self)))
        Set psStartupBitmapPath  to (psBitmapPath(phoWorkspace(Self)))

        Get phoCommandLine to hoCmdLine
        Get CountOfArgs of hoCmdLine to iNumArgs

        For iCount from 1 to iNumArgs
            Get Argument of hoCmdLine iCount to sArgument   
            Move (Left(sArgument, 1)) to sChar
            If (sChar = "-") Begin
                Move (Replace("-", sArgument, "/")) to sArgument
            End
            Move (Lowercase(sArgument)) to sArgument

            Case Begin
                Case (sArgument = CS_CmdLineDebug)
                    Move True to bDebugMode
                    Case Break

                Case (sArgument = CS_CmdLineHelp1 or sArgument = CS_CmdLineHelp2 or sArgument = CS_CmdLineHelp3 or sArgument = CS_CmdLineHelp4)
                    Move True to bShowParamHelp
                    Case Break

                Case (sArgument = CS_CmdLineSWSFile)
                    Get Argument of hoCmdLine (iCount + 1) to sSWSFile
                    Move (Trim(sSWSFile)) to sSWSFile
                    Case Break
                                    
                Case (sArgument = CS_CmdLineFileName1 or sArgument = CS_CmdLineFileName2)
                    Get Argument of hoCmdLine (iCount + 1) to sSourceFile
                    Case Break
                
                Case (sArgument = CS_CmdLineFolders1 or sArgument = CS_CmdLineFolders2 or sArgument = CS_CmdLineFolders3)
                    Get Argument of hoCmdLine (iCount + 1) to sFolders
                    Case Break

                Case (sArgument = CS_CmdLineBatch1 or sArgument = CS_CmdLineBatch2)
                    Move True to bBatch
                    Case Break
                
                Case (sArgument = CS_CmdConfigFile1 or sArgument = CS_CmdConfigFile2)
                    Get Argument of hoCmdLine (iCount +1) to sCmdLineIniFile
                    Get ParseFolderName sCmdLineIniFile to sPath
                    If (sPath = "") Begin
                        Get psHome of (phoWorkspace(ghoApplication)) to sPath
                        Get vFolderFormat sPath to sPath
                        Move (sPath + sCmdLineIniFile) to sCmdLineIniFile
                    End
                    Set psCmdLineIniFile to sCmdLineIniFile
                    Move True to bConfigFile
                    Move True to bBatch
                    Case Break
            Case End
        Loop
        
        If (bShowParamHelp = True) Begin
            Move "" to sParamText
            Append sParamText "PARAMETER SYNTAX:"
            Append sParamText "\n=============="

            Append sParamText "\n\n/h or /help or /? - Displays *this* help text. Then exits the program."
            Append sParamText "\n\n/debug - displays all passed parameters. Then exits the program."
            Append sParamText " The /h takes precedence over the /debug flag."
            Append sParamText "\nIf the /batch flag is omitted, the program will wait for the user to start the process."
            Append sParamText "\n\nNote: Parameters and its value(s) must all be passed as a pair separated by a SPACE, when applicable."
            Append sParamText "\nParameters can be passed in any order."
            Append sParamText "\n\nPaths should be surrounded by single- or double-quotes('""')"
            Append sParamText "\nOnly parameters that are necessary needs to be passed."
            Append sParamText "\nUppercase/Lowercase doesn't matter when spelling flags."
            Append sParamText "\nEach flag must be preceeded by a '/' (forward slash) or a '-' (dash) character."
                              
            Append sParamText "\n\nFLAGS AND SAMPLE USAGE:"
            Append sParamText "\n========================"

            Append sParamText "\n *.sws workspace file:"
            Append sParamText '\n/sws "C:\Projects\DF20\My_Folder\MySWSFile.sws"'
            Append sParamText "\nMandatory, if not the /c flag is used."
            
            Append sParamText "\n\nSingle Source File:"
            Append sParamText "\n/f or /file - A single file name with full path."
            Append sParamText '\n/f "C:\Projects\DF20\My_Folder\AppSrc\MySourceFile.vw"' 
            Append sParamText "A Single Source File takes precedence over a *.sws workspace file."
            
            Append sParamText "\n\nFolder Names Selections:"
            Append sParamText "\n/d or /dirs or /folders - followed by a semi-comma separated list with folder names to be selected."
            Append sParamText "\nThe semi-comma separated list with folders will be added to those previously saved for the workspace."
            Append sParamText "\n/d AppSrc;DDSrc;AppHtml;Libraries (only together with the /sws param)"

            Append sParamText "\n\nBatch mode - Automatically start and run a refactoring silently:"
            Append sParamText "\nThe running program's UI will be shown on screen, but there will be no user interaction."
            Append sParamText "\n/batch"
            Append sParamText "\nIf omitted, program will start, display the passed parameters, but *will not* start automatically."

            Append sParamText '\n\n/c or /config - Use an ini-file:'
            Append sParamText "\n/c " CS_CmdIniFileName 
            Append sParamText "\nThat is the default ini-file name."
            Append sParamText "\nThe default location is the Home folder. Else the full path and name must be specified."
            Append sParamText "\nNote: If the /c or /config flag is used, it overrules the /batch flag, to always be true."
            Append sParamText "\nTop Tip: On the 'Program Settings' dialog, there is an 'Export to ini-file' button, that exports current"
            Append sParamText "\nworkpace settings to an ini-file of choice, so there is no need to create one from scratch."

            Send Info_Box sParamText
            Abort 
        End 
        
        If (bDebugMode = True) Begin
            Move "Parameters passed on the command line:" to sParamText
            Append sParamText "\n\nDebug mode:"
            Append sParamText "\n/debug = TRUE"

            Append sParamText "\n\n *.sws param and file:"
            If (sSWSFile <> "") Begin
                Append sParamText "\n/sws " sSWSFile
            End
            Else Begin
                Append sParamText "\n/sws " "None specified"
            End
                    
            Append sParamText "\n\nSingle Source File:"
            If (sSourceFile <> "") Begin
                Append sParamText "\n/f " sSourceFile
            End
            Else Begin
                Append sParamText "\n/f " "None specified"
            End
            
            Append sParamText "\n\n Folder Names:"
            If (sFolders <> "") Begin
                Append sParamText "\n/f " sFolders
            End
            Else Begin
                Append sParamText "\n/f " "None specified"
            End
                
            Append sParamText "\n\nBatch mode:"
            Append sParamText "\n/batch = " (If(bBatch = True, "TRUE", "FALSE"))
            Append sParamText "\nIf omitted, program will start, display the passed parameters, but *will not* start automatically."
            
            Append sParamText "\n\nIni-file:"
            If (sCmdLineIniFile <> "") Begin
                Append sParamText "\n" sCmdLineIniFile
                Append sParamText "\n/batch = TRUE"
            End
            Else Begin
                Append sParamText "\n" "None specified"
            End
                    
            Send Info_Box sParamText
            Abort 
        End

        // We need to send messages in this order:
        If (sSWSFile <> "") Begin
            If (bConfigFile = False) Begin
                Set pbWorkspaceMode to True
                Send UpdateWorkspaceSelectorDisplay sSWSFile
            End
            Else Begin
                Send Stop_Box "You need to specify an .sws file on the command line! Program will now stop."
                Abort    
            End
        End
        Else If (sSourceFile <> "") Begin
            Set pbWorkspaceMode to False
            Send OnFileNameUpdate sSourceFile
        End
        If (sFolders <> "") Begin
            Move (StrSplitToArray(sFolders, ";")) to asFolders
            Set pasCmdLineSetSelectedFolders to asFolders
        End 
        If (bBatch = True) Begin
            Set pbBatchMode to True
        End
        If (bConfigFile = True) Begin
            Set pbBatchMode to True
            Send ReadCmdLineIniFile sCmdLineIniFile     
        End
    End_Procedure
    
    // Helper message for: Command Line Interface:
    Procedure ReadCmdLineIniFile String sCmdLineIniFile
        Handle hoIni hoDD
        String sSWSFile sUserName sFolder sFilters sFunction sFileName sText
        String[] asFolders asFunctions
        Boolean bFolders bExists
        Integer iCount iSize
        
        File_Exist sCmdLineIniFile bExists
        If (bExists = False) Begin
            Send Stop_Box ("The CmdLineIniFile can't be found:" * String(sCmdLineIniFile) + "\nThe program will now close.")
            Abort
        End
            
        Get Create (RefClass(cIniFile)) to hoIni
        Set psFileName of hoIni to sCmdLineIniFile
        
        // SWS-File:
        Get ReadString of hoIni CS_CmdIniSWSFileSection CS_CmdIniSWSFile (psSWSFile(Self)) to sSWSFile
        If (sSWSFile <> "") Begin
            Set pbWorkspaceMode to True
            Send UpdateWorkspaceSelectorDisplay sSWSFile
        End
        Else Begin           
            Get psSWSFile to sFileName
            If (sFileName = "") Begin 
                If (sCmdLineIniFile <> "")
                Send Stop_Box ("The .sws file is missing from the ini-file and has not been specified on the command line. Cannot continue. Program will now close.")
                Abort
            End
        End

        // User Name:
        Get ReadString of hoIni CS_CmdIniUserSection CS_CmdIniUserName "" to sUserName
        If (sUserName <> "") Begin
            Set psUsername to sUserName
        End
                
        // Folders:
        Move 1000 to iSize // Just an arbitrarly large integer.
        For iCount from 1 to iSize
            Get ReadString of hoIni CS_CmdIniFoldersSection (CS_CmdIniFolderName + String(iCount)) "" to sFolder
            If (sFolder = "") Begin
                Move iSize to iCount
            End
            Else Begin
                Move sFolder to asFolders[-1]
            End
        Loop
        // Update Folders table selections
        Set pasCmdLineSetSelectedFolders to asFolders
            
        // Filters:
        Get ReadString of hoIni CS_CmdIniFileFilterSection CS_CmdIniFileFilters "" to sFilters
        If (sFilters <> "") Begin
            Open SysFile
            Move sFilters to SysFile.FileExtensionFilter
            SaveRecord SysFile
        End
        
        // Functions:
        For iCount from 1 to iSize
            Get ReadString of hoIni CS_CmdIniFunctionSection (CS_CmdInitFunction + String(iCount)) "" to sFunction
            If (sFunction = "") Begin
                Move iSize to iCount
            End
            Else Begin
                Move sFunction to asFunctions[-1]
            End
        Loop
        // Update Functions table selections
        Get Create (RefClass(cFunctionsDataDictionary)) to hoDD
        Send UnSelectAllRecords of hoDD
        Send SelectRecordsFromStringArray of hoDD asFunctions    
        
        Send Destroy of hoDD        
        Send Destroy of hoIni
    End_Procedure
    
End_Object

// *** Include Main Refactoring Functions ***
// Object is of the cRefactorFuncLib class.
Use oRefactorFuncLib.pkg

// *** Create the Refactor Engine ***
Use cRefactorEngine.pkg
Get Create (RefClass(cRefactorEngine)) to ghoRefactorEngine
Set Name of ghoRefactorEngine to "oRefactorEngine"
Set pbBatchMode of ghoRefactorEngine to (pbBatchMode(ghoApplication))


Use cDbUpdateHandler.pkg
Object oDbUpdateHandler is a cDbUpdateHandler
    Set piDbVersionFileNumber  to 363 // DbVersion table
    Set piDbVersionFieldNumber to 1
    Set pbAutoCreateDbVersionTable to True   
    Set pbUseIntFilesBackup to True
    Set piIntFilesFileNumber to 364
    Set pbContinueOnError to True
    Set pbEnableCancelButton to True

//    Use DUF_MultipleTables1_0.pkg
//    Use DUF_MultipleTables1_1.pkg
//    Use DUF_MultipleTables1_2.pkg
//    Use DUF_MultipleTables1_3.pkg
    Use DUF_MultipleTables1_4.pkg
End_Object
                                
Use SelectWorkspace.dg
If (pbBatchMode(ghoApplication) = False) Begin
    Send Popup of oSelectWorkspace_dg
End


Use cRDCTooltipController.pkg
Object oToolTipController is a cRDCTooltipController
End_Object

Open SysFile
Open StatLog
Register_Object oSysfile_DD

Use cRDCCJSelectionGrid.pkg // Needed for Struct tFolderData
Use cSciLexer.h
Use oEditorProperties.pkg
Use oEditContextMenu.pkg
Use oDEOEditContextMenu.pkg

Object oMain is a Panel
    Set Label to (psProduct(ghoApplication) * "- Refactor DataFlex Legacy Source Code")
    Set Size to 310 550
    Set piMinSize to 294 550
    Set Icon to "DFRefactor.ico"

    Object oCJCommandBarSystem is a cRDCCJCommandBarSystem

        Object oWorkspace_Toolbar is a cCJToolbar
            Set pbDockNextTo to False
            Set peStretched to stStretchShared
            Set pbCloseable to False
            Set pbCustomizable to False

            Object oWorkspaceSelectorText_Menuitem is a cCJMenuItem
                Set psCaption to CS_SelectWorkspaceText
                Set psToolTip to "Select Workspace"
                Set psDescription to  (CS_SelectWorkspaceFile * String("Alt+W"))
                Set psImage to "ActionOpenWorkspace.ico"
                Set peControlType to xtpControlCustom
                Set peControlStyle to xtpButtonIconAndCaption

                Procedure OnExecute Variant vCommandBarControl
                    Send Execute of (oWorkspaceOpen_Menuitem(ghoCommandBars))
                End_Procedure

                Procedure OnCreateControl Handle hoObj
                    Set ComDefaultItem of hoObj to True
                End_Procedure
                    
            End_Object

            Object oWorkspaceSelector_Menuitem is a cCJWorkspaceComboMenuItem
                Set psToolTip to "Recent Workspaces"
                Set psImage to "ActionOpenWorkspace.ico"
                Set peControlType to xtpControlComboBox
                Set phoWorkspaceSelector_Menuitem of ghoApplication to Self
                Set phoWorkspaceSelectorText_MenuItem to (oWorkspaceSelectorText_Menuitem(ghoCommandBars))
                Set phoClear_MenuItem        to (oClear_MenuItem(ghoCommandBars))
            End_Object

            Object oWorkspaceOpen_Menuitem is a cCJMenuItem
                Set psToolTip to "Open Workspace File"
                Set psDescription to  (CS_SelectWorkspaceFile * String("(Alt+W)"))
                Set psShortcut to "Alt+W"
                Set pbControlCloseSubMenu to False
                Set pbControlFlagNoMovable to True
                Set psImage to "ActionOpen.ico"
                Set peControlStyle to xtpButtonIcon

                Procedure OnExecute Variant vCommandBarControl
                    String sFileName
                    Get SelectWorkspaceFile of ghoApplication to sFileName
                    If (sFileName <> "") Begin
                        Send UpdateWorkspaceSelectorDisplay of ghoApplication sFileName
                        Send DisplayWorkspaceItem of (oWorkspaceSelector_Menuitem(ghoCommandBars)) sFileName
                    End
                End_Procedure
                
            End_Object

            Object oRadioSelectorText_Menuitem is a cCJMenuItem
                Set psCaption to "Mode:"
                Set psToolTip to "Refactoring Mode"
                Set psDescription to "Select if the refactoring should run on all source files that matches the 'File extensions' combo for selected workspace, or only on one selected file. (Toggle with Alt+F)"
                Set pbControlBeginGroup to True
                Set pbActiveUpdate to True
                Set peControlStyle to xtpButtonIconAndCaption

                Procedure OnExecute Variant vCommandBarControl

                    Forward Send OnExecute vCommandBarControl
                    Send Execute of oWorkspaceRadio_MenuItem
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function

            End_Object

            Object oWorkspaceRadio_MenuItem is a cCJMenuItem
                Set peControlType to xtpControlRadioButton
                Set psCaption to "All Files"
                Set psToolTip to "All files mode"
                Set psDescription to "Select if the refactoring should run on all source files that matches the 'File Filter' combo for selected workspace. Toggles with (Alt+F)"
                Set pbChecked to True
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Boolean bState
                    Get pbChecked to bState
                    Set pbChecked to (not(bState))
                    Set pbWorkspaceMode of ghoApplication to (not(bState))
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function

                Procedure OnCreateControl Handle hoObj
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Set pbChecked to (sSWSFile <> "")
                    Set ComDefaultItem of hoObj to True
                End_Procedure

            End_Object

            Object oFileRadioMenuItem is a cCJMenuItem
                Set peControlType to xtpControlRadioButton
                Set psCaption to "Single &File"
                Set psToolTip to "Mode"
                Set psDescription to "Select if the refactoring should be run on one selected source file only (use the 'Open Source File:' to select) Toggles with (Alt+F)"
                Set psShortcut to "Alt+F"
                Set pbActiveUpdate to True
                
                Procedure OnExecute Variant vCommandBarControl
                    Boolean bState
                    Get pbChecked to bState
                    Set pbChecked to (not(bState))
                    Set pbWorkspaceMode of ghoApplication to bState
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function

                Procedure OnCreateControl Handle hoObj
                    String sSWSFile sSourceFile
                    Forward Send OnCreateControl hoObj
                    Get psSWSFile of ghoApplication to sSWSFile
                    Get psCurrentSourceFileName of ghoApplication to sSourceFile
                    Set pbChecked to (sSWSFile <> "")
                    Set pbWorkspaceMode of ghoApplication to (sSourceFile = "")
                    Set ComDefaultItem of hoObj to True
                End_Procedure

            End_Object

        End_Object

        Object oSourceFile_Toolbar is a cCJToolbar
            Set pbEnableDocking to False
            Set pbCloseable to False
            Set pbCustomizable to False
            Set pbShowExpandButton to False
            Set peStretched to stStretchShared

            Object oOpenFolderMenuItem is a cCJMenuItem
                Set psCaption to CS_BrowseSourceFileTxt
                Set psToolTip to "Select source file"
                Set psDescription to "Displays an Open File dialog to select a SINGLE source file from (Ctrl+O). This will automatically set the 'Refactoring Mode' to 'Single File'"
                Set psImage to "ActionOpen.ico"
                Set peControlStyle to xtpButtonIconAndCaption
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Forward Send OnExecute vCommandBarControl
                    Send SelectSourceFile of ghoApplication
                End_Procedure

                Function IsEnabled Returns Boolean
                    Boolean bState
                    Move False to bState
                    Get pbWorkspaceMode of ghoApplication to bState
                    Function_Return (bState = False)
                End_Function

            End_Object

            Object oSourceFileText_MenuItem is a cCJMenuItem
                Set peControlType to xtpControlCustom

                Procedure OnExecute Variant vCommandBarControl
                    Forward Send OnExecute vCommandBarControl
                    Send Execute of oOpenFolderMenuItem
                End_Procedure
            End_Object

        End_Object

        Object oEditToolBar is a cCJToolbar
            Set psTitle to "Edit Toolbar"
            Set peStretched to stStretchShared
            Set pbCloseable to False
            Set pbCustomizable to False

            Object oClear_MenuItem is a cCJMenuItem
                Set pbControlBeginGroup to True
                Set pbActiveUpdate to True
                Set psCaption to "Clear"
                Set psToolTip to "Clear Workspace/File"
                Set psDescription to "Clears the currently selected workspace/or File depending on the selected mode"
                Set psImage to "ActionClear.ico"
                Set peControlStyle to xtpButtonIconAndCaption

                Procedure OnExecute Variant vCommandBarControl
                    Boolean bChanged bMode
                    Integer iRetval
                    Handle hoEditor

                    Broadcast Recursive Get pbShouldSave of (Client_Id(phoMainPanel(ghoApplication))) to bChanged
                    If (bChanged = True) Begin
                        Get YesNo_Box ("Changes exists! If you answer 'Yes' your changes will be lost. Are you sure?") "" MB_DEFBUTTON2 to iRetval
                        If (iRetval <> MBR_Yes) Begin
                            Procedure_Return
                        End
                    End
                    
                    Send UpdateWorkspaceSelectorDisplay of ghoApplication ""
                    Get phoEditor of ghoApplication to hoEditor
                    Send Request_Clear of hoEditor
                    Set pbWorkspaceMode of ghoApplication to True
                    Send Activate_oRefactorView of (Client_Id(ghoCommandBars))
                    Broadcast Recursive Send Request_Clear of (oRefactorView(Client_Id(ghoCommandBars)))
                    Send Request_Switch_To_Tab of (oMain_TabDialog(phoRefactorView(ghoApplication))) 0 1
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function

            End_Object

            Object oSave_ToolItem is a cCJSaveMenuItem
                Set peControlStyle to xtpButtonIcon
                Set psCaption to "&Save"
                Set psToolTip to "Save"
                Set psDescription to "Save editor changes (Alt+S)"
                Set psShortcut to "Alt+S"

                Function IsEnabled Returns Boolean
                    Boolean bChanged

                    Move False to bChanged
                    If (oSysfile_DD(phoRefactorView(ghoApplication))) Begin
                        Get Should_Save of (oSysfile_DD(phoRefactorView(ghoApplication))) to bChanged
                    End
                    If (bChanged = False) Begin
                        Get pbShouldSave of (phoEditorView(ghoApplication)) to bChanged
                    End
                    If (bChanged = False) Begin
                        Get pbShouldSave of (phoRefactorView(ghoApplication)) to bChanged
                    End
                    Function_Return bChanged
                End_Function

                Procedure OnExecute Variant vCommandBarControl
                    Send Request_Save of (Focus(Self))
                End_Procedure

            End_Object

            Object oDeleteEditToolbarItem is a cCJDeleteEditMenuItem
            End_Object

            Object oUndo_MenuItem is a cCJMenuItem
                Set psToolTip to "Undo"
                Set psDescription to "Undo last editor action (Ctrl+Z)"
                Set psImage to "ActionUndo.ico"
                Set pbActiveUpdate to True
                Set pbControlBeginGroup to True

                Procedure OnExecute Variant vCommandBarControl
                    Send CME_UndoAction of (Focus(Desktop))
                End_Procedure

                Function IsEnabled Returns Boolean
                    Boolean bCanUndo
                    Get Can_UndoAction of (Focus(Desktop)) to bCanUndo
                    Function_Return bCanUndo
                End_Function

            End_Object

            Object oRedo_MenuItem is a cCJMenuItem
                Set psToolTip to "Redo"
                Set psDescription to "Redo last editor action (Ctrl+Z)"
                Set psImage to "ActionRedo.ico"
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Send CME_RedoAction of (Focus(Desktop))
                End_Procedure

                Function IsEnabled Returns Boolean
                    Boolean bCanRedo
                    Get Can_RedoAction of (Focus(Desktop))  to bCanRedo
                    Function_Return bCanRedo
                End_Function

            End_Object

            Object oCutToolbarItem is a cCJCutMenuItem
                Set pbControlBeginGroup to True
            End_Object
    
            Object oCopyToolbarItem is a cCJCopyMenuItem
            End_Object
    
            Object oPasteToolbarItem is a cCJPasteMenuItem
            End_Object

        End_Object

        Object oActions_Toolbar is a cCJToolbar
            Set psTitle to "Action Toolbar"
            Set peStretched to stStretchShared
            Set pbCloseable to False
            Set pbCustomizable to False
            Set pbDockNextTo to False

            Object oRefactor_ToolItem is a cCJMenuItem
                Set pbControlBeginGroup to True
                Set pbActiveUpdate to True
                Set peControlStyle to xtpButtonIconAndCaption
                Set psCaption to "Start &Refactoring"
                Set psToolTip to "Refactor code with the selected functions and Mode: All Files/One File (Ctrl+F5)"
                Set psDescription to "Refactor Code (Ctrl+F5)"
                Set psImage to "Start.ico"
                Set psShortcut to "Ctrl+F5"
                Set pbActiveUpdate to True
                
                Procedure OnExecute Variant vCommandBarControl
                    Send RefactoreCode of (phoRefactorView(ghoApplication))
                End_Procedure

                Function IsEnabled Returns Boolean
                    Boolean bEnabled bWorkspaceMode
                    String sFileName sSWSFile sHomePath
                    Integer iSelectedFunctions iFolders
                    Handle hoFolderSelHeaDD
                    Boolean bExists bUseDDO
                    tFolderData[] asSavedFolders
    
                    Get pbWorkspaceMode         of ghoApplication to bWorkspaceMode
                    Get psSWSFile               of ghoApplication to sSWSFile
                    Get psCurrentSourceFileName of ghoApplication to sFileName
    
                    If (bWorkspaceMode = True) Begin
                        Move (sSWSFile <> "") to bEnabled
                    End
                    Else Begin
                        Move (sFileName <> "") to bEnabled
                    End
    
                    If (bEnabled = True) Begin
                        Move (SysFile.SelectedFunctionTotal > 0) to bEnabled
                    End
                    If (bEnabled = True and bWorkspaceMode = True) Begin
                        Get TotalSelectedFolders of (phoFolderSelHeaDD(ghoApplication)) to iFolders
                        Move (iFolders <> 0) to bEnabled
                    End
                    If (bEnabled = False) Begin
                        Move SysFile.bCountSourceLines to bEnabled
                    End
    
                    Function_Return bEnabled
                End_Function

                Procedure OnCreateControl Handle hoObj
                    Set ComDefaultItem of hoObj to True
                End_Procedure
                
            End_Object
        
            Object oCompare_MenuItem is a cCJMenuItem
                Set psCaption to "Co&mpare"
                Set psToolTip to "Compare"
                Set psDescription to "Compare file changes after running refactoring function(s) (Alt+M)"
                Set psImage to "Compare.ico"
                Set peControlStyle to xtpButtonIconAndCaption
                Set pbActiveUpdate to True
                Set pbControlBeginGroup to True

                Procedure OnExecute Variant vCommandBarControl
                    String sCompareApp
                    Boolean bWorkspaceMode

                    Forward Send OnExecute vCommandBarControl
                    Get psFileCompareApp of ghoApplication to sCompareApp
                    Get pbWorkspaceMode of ghoApplication to bWorkspaceMode
                    If (bWorkspaceMode = True) Begin
                        Send ComparePaths of ghoApplication sCompareApp
                    End
                    Else Begin
                        Send CompareFiles of ghoApplication sCompareApp
                    End
                End_Procedure

                Function IsEnabled Returns Boolean
                    Boolean bOK
                    tsSearchResult[] BackpupFileArray
                    Move False to bOK
                    Get AllBackupFolderFiles of ghoApplication to BackpupFileArray
                    Move (SizeOfArray(BackpupFileArray) <> 0) to bOK
                    Function_Return bOK
                End_Function

            End_Object

            Object oOpenLogFile_MenuItem is a cCJMenuItem
                Set psToolTip to "View log file"
                Set psDescription to "View the logfile that is added to for each run (Alt+L)"
                Set psImage to "OpenLogFile.ico"
                Set peControlStyle to xtpButtonIcon
                Set pbControlBeginGroup to True
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Send ShowLogFile of ghoApplication
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sPath sLogFile
                    Boolean bLogFileExists

                    Get psHomePath of ghoApplication to sPath
                    Get vFolderFormat sPath to sPath
                    Move (sPath + CS_BackupFolder + CS_DirSeparator + CS_SummaryLogfileName) to sLogFile
                    Get vFilePathExists sLogFile to bLogFileExists

                    Function_Return (bLogFileExists = True)
                End_Function

            End_Object

            Object oOpenOtherLogFile_MenuItem is a cCJMenuItem
                Set psToolTip to "Other log files"
                Set psDescription to "View a list of log files created by functions of type: 'eOther_Function"
                Set psImage to "OtherLogFiles.ico"
                Set peControlStyle to xtpButtonIcon
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Send ShowOtherLogFiles of ghoApplication
                End_Procedure

                Function IsEnabled Returns Boolean
                    String[] asOtherLogFiles
//                    Get pasOtherLogFiles of ghoRefactorFuncLib to asOtherLogFiles
                    Get OtherLogFiles of ghoApplication to asOtherLogFiles
                    Function_Return (SizeOfArray(asOtherLogFiles) > 0)
                End_Function

            End_Object

            Object oShowErrorLog_MenuItem is a cCJMenuItem
                Set psToolTip to "View Refactor Engine Error Log"
                Set psDescription to "View the refactor engine error log"
                Set psImage to "ErrorLog.ico"
                Set peControlStyle to xtpButtonIcon
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Send Popup of (oEngineErrorLog_dg(Client_Id(ghoCommandBars)))
                End_Procedure
                
                Function IsEnabled Returns Boolean
                    Integer iErrors
                    Get_Attribute DF_FILE_RECORDS_USED of StatLog.File_Number to iErrors
                    Function_Return (iErrors > 0)
                End_Function

            End_Object

            Object oUndoRefactoring_MenuItem is a cCJMenuItem
                Set psToolTip to "Undo Refactoring"
                Set psDescription to "Undo process of refactoring actions. Dialog that moves files from the 'DFRefactor Backup' subfolder structure to their original folders. (Alt+U)"
                Set psImage to "UndoRefactoring.ico"
                Set pbActiveUpdate to True
                Set pbControlBeginGroup to True

                Procedure OnExecute Variant vCommandBarControl
                    tsSearchResult[] BackpupFileArray
                    Forward Send OnExecute vCommandBarControl
                    Send Cursor_Wait of Cursor_Control
                    Get AllBackupFolderFiles of ghoApplication to BackpupFileArray
                    Send Cursor_Ready of Cursor_Control
                    Send FillBackupFilesDialog of (Client_Id(ghoCommandBars)) BackpupFileArray
                End_Procedure

                Function IsEnabled Returns Boolean
                    Boolean bOK
                    tsSearchResult[] BackpupFileArray
                    Move False to bOK
                    Get AllBackupFolderFiles of ghoApplication to BackpupFileArray
                    Move (SizeOfArray(BackpupFileArray) <> 0) to bOK
                    Function_Return bOK
                End_Function

            End_Object

        End_Object
        
        Object oTools_toolbar is a cCJToolbar
            Set peStretched to stStretchShared
            Set pbCloseable to False
            Set pbCustomizable to False
            Set pbDockNextTo to True

            Object oOpenContainingFolder_MenuItem is a cCJMenuItem
                Set psImage to "ActionOpenContainingFolder.ico"
                Set psCaption to "Containing Folder"
                Set psToolTip to "Open Folder"
                Set psDescription to "Open Containing Folder"
                Set pbActiveUpdate to True
                Set pbControlBeginGroup to True

                Procedure OnExecute Variant vCommandBarControl
                    String sPath sFile
                    Get psWorkspaceHomePath of ghoApplication to sPath
                    Get psCurrentSourceFileName of ghoApplication to sFile
                    
                    // We want to have that file to be selected in Windows Explorer
                    If (sFile <> "") Begin
                        Move ("/select," * String(sFile)) to sPath
                    End
                    Send vShellExecute "open" "explorer.exe" sPath ""
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sPath
                    Get psWorkspaceHomePath of ghoApplication to sPath
                    Function_Return (sPath <> "")
                End_Function

            End_Object

            Object oCodeExplorer_ToolbarButton is a cCJMenuItem
                Set psCaption to "StarZens Source &Explorer"
                Set psToolTip to "DataFlex Source Explorer"
                Set psDescription to "Run Starzen's DataFlex Source Code Explorer (Alt+E)"
                Set psImage to "DataFlexSourceExplorer.ico"
                Set psShortcut to "Alt+E"
                Set peControlStyle to xtpButtonIcon
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    String sProgram sSWSPath
                    
                    Get private.psStarZenSourceExplorer of ghoApplication to sProgram
                    If (sProgram = "") Begin
                        Send Info_Box "You first need to setup the path to StarZen's Source Code Explorer program with 'Program Settings'"
                        Procedure_Return
                    End
                    Get psSWSFile of ghoApplication to sSWSPath
                    If (sSWSPath <> "") Begin
                        Move ("-ws" * '"' + sSWSPath + '"') to sSWSPath
                    End
                    Runprogram Background sProgram sSWSPath
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sProgram sSWSPath
                    Get psStarZenSourceExplorer of ghoApplication to sProgram
                    Get psSWSFile of ghoApplication to sSWSPath
                    Function_Return (sProgram <> "" and sSWSPath <> "")
                End_Function

            End_Object

        End_Object

        Object oSettings_toolbar is a cCJToolbar
            Set peStretched to stStretchShared
            Set pbCloseable to False
            Set pbCustomizable to False

            Object oSettings_Toolbarbutton is a cCJMenuItem
                Set psToolTip to "Program Settings"
                Set psCaption to "Se&ttings"
                Set psDescription to "Program Settings (Alt+T)"
                Set psImage to "Settings.ico"
                Set peControlStyle to xtpButtonIcon
                Set pbControlBeginGroup to True
                Set psShortcut to "Alt+T"
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Send Popup of (oProgramSetup_dg(Client_Id(ghoCommandBars)))
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function

            End_Object

            Object oScintillaEditorSettings_Mentuitem is a cCJMenuItem
                Set psToolTip to "Editor Settings" 
                Set psCaption to "E&ditor Settings"
                Set psDescription to "Configure the editor (Alt+D)"
                Set psImage to "EditorSettings.ico"
                Set peControlStyle to xtpButtonIcon
                Set psShortcut to "Alt+D"
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Send Popup of (oScintillaParameters_dg(Client_Id(ghoCommandBars)))
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function

            End_Object

#IFDEF Is$BlingStuff
            #Include CosmeticToolbarItems.pkg
#ENDIF
        End_Object

        Object oExit_toolbar is a cCJToolbar
            Set pbCloseable to False
            Set pbCustomizable to False
            Set pbShowExpandButton to False
            Set peStretched to stStretchShared

            Object oAbout_MenuItem is a cCJAboutMenuItem
                Set pbActiveUpdate to True
                Set psCaption to C_$CaptionAbout
                Set psDescription to C_$DescAbout
                Set psToolTip to C_$ToolTipAbout
                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function
            End_Object

            Object oKoFi_MenuItem is a cCJMenuItem
                Set psCaption to "Ko-fi"
                Set psToolTip to "Coffee Time!"
                Set psDescription to "Buy me a coffee, to support me"
                Set psImage to "Ko-fi.ico"
                Set pbControlBeginGroup to True
                Procedure OnExecute Variant vCommandBarControl
                    Runprogram Shell Background "https://ko-fi.com/nilss"
                End_Procedure
            End_Object

            Object oSuggestion_MenuItem is a cCJMenuItem
                Set psTooltip to "Suggest"
                Set psDescription to "Suggest a feature, or report a bug..."
                Set psImage to "Suggestion.ico"
                Set pbControlBeginGroup to True

                Procedure OnExecute Variant vCommandBarControl
                    Runprogram Shell Background "https://github.com/NilsSve/DfRefactor/issues"
                End_Procedure

            End_Object

            Object oHelpMenu is a cCJMenuItem
                Set psCaption to "Help"
                Set psToolTip to "Help"
                Set psDescription to "Help about the program (F1)"
                Set psImage to "ActionHelp.ico"
                Set peControlType to xtpControlSplitButtonPopup
                Set pbActiveUpdate to True

                Procedure OnExecute Variant vCommandBarControl
                    Runprogram Shell Background "https://www.rdctools.com/DFRefactor/index.html"
                End_Procedure

                Function IsEnabled Returns Boolean
                    String sSWSFile
                    Get psSWSFile of ghoApplication to sSWSFile
                    Function_Return (sSWSFile <> "")
                End_Function

                Object oHelpMenuItemLocal is a cCJHelpMenuItem
                    Set psCaption to "Local HTML Help"
                End_Object

                Object oHelpMenuItemInternetBrowser is a cCJMenuItem
                    Set psCaption to "Online HTML Help"
                    Set psImage to "ActionHelpInternet.ico"
                    Procedure OnExecute Variant vCommandBarControl
                        Runprogram Shell Background "https://www.rdctools.com/DFRefactor/index.html"
                    End_Procedure

                End_Object

                Object oHelpGitHub is a cCJMenuItem
                    Set psCaption to "GitHub source code repository"
                    Set psToolTip to "Link to GitHub source code repository"
                    Set psDescription to "Github source code"
                    Set psImage to "GitHub.ico"
                    Set pbControlBeginGroup to True
                    Procedure OnExecute Variant vCommandBarControl
                        Forward Send OnExecute vCommandBarControl
                        Runprogram Shell Background "https://github.com/NilsSve/DFRefactor.git"
                    End_Procedure
                End_Object
                
            End_Object

            Object oExitMenuItem is a cCJExitMenuItem
                Set psImage to "ActionExit.ico"
                Set psToolTip to "Exit"
                Set psDescription to "Exit the program (Alt+F4)"
                Set pbControlBeginGroup to True
            End_Object

        End_Object

        Object oStatusBar is a cCJStatusBar
            Set StatusBar_Id to Self

            Object oStatusPane1 is a cCJStatusBarPane
                Set piID to sbpIDIdlePane
                Set pbStyleStretch to True
            End_Object

            Object oStatusPane2 is a cCJStatusBarPane
                Set phoViewPane to Self
                Set pbStyleStretch to True
            End_Object

            // Made these objects mimic NotePad++
            Object oNumberOfCharacters_StatusbarPane is a cCJStatusBarPane
                Set psText to "length:"
            End_Object

            Object oNumberOfLines_StatusbarPane is a cCJStatusBarPane
                Set psText to "lines:"
            End_Object

            Object oUTF8_OEM_Text is a cCJStatusBarPane
                Set psText to "OEM"
            End_Object

            Procedure Set NumberOfEditorLines String sText
                Move (FormatValue(sText, ",###")) to sText
                Set psText of oNumberOfLines_StatusbarPane to ("lines:" * String(sText))
            End_Procedure

            Procedure Set NumberOfEditorCharacters String sText
                Move (FormatValue(sText, ",###")) to sText
                Set psText of oNumberOfCharacters_StatusbarPane to ("length:" * String(sText))
            End_Procedure

            Procedure Set StatusText String sText
                Set psText of oStatusPane1 to sText
            End_Procedure                          
            
            Procedure Set ActionText String sText
                Handle hoViewPane
                Get phoViewPane to hoViewPane
                Set psText of hoViewPane to sText
            End_Procedure

            Procedure Set UTF8Text String sText
                Set psText of (oUTF8_OEM_Text(Self)) to sText
            End_Procedure
            
        End_Object

    End_Object

    Object oClientArea is a ClientArea
//        Use Dd_debug.dg
        Use ProgramSetup.dg
        Use ScintillaParameters.dg
        Use EngineErrorLog.dg
        Use BackupFiles.dg
        Use EngineLogFile.dg
        Use ShowOtherLogFiles.dg
        
        Use RefactorView.vw
        Use EditorView.vw

        Use oEditorProperties.pkg
        Use StdAbout.pkg

        Procedure Activate_About  
            String sTestGroup     
            // Below logic in DFAbout has been replaced, so if the first four parameters are blank, an About.rtf file
            // in the Help folder, will be read into the cRichEdit object of hte DFAbout dialog.
            Send DoAbout "" "" "" "" "DFRefactor72x72.bmp"
        End_Procedure

        // We don't allow closing of a view - it just doesn't make
        // sense with a tabbed interface.
        Function Exit_Loss_Confirmation For cUIObject Returns Integer
            Function_Return 1
        End_Function

        Function Verify_Exit_Application Returns Integer
            Integer iFail iRetval
            Boolean bChanged

            Move 0 to iFail
            Broadcast Recursive Get pbShouldSave to bChanged
            If (bChanged = True) Begin
                Get YesNoCancel_Box "Changes exists! Do you want to save changes?" "" MB_DEFBUTTON3 to iRetval
                If (iRetval = MBR_Yes) Begin
                    Send Execute of (oSave_ToolItem(ghoCommandBars))
                    Move 0 to iFail
                End
                If (iRetval = MBR_No) Begin
                    Move 0 to iFail
                End
                If (iRetval = MBR_Cancel) Begin
                    Move 1 to iFail
                End
            End
            Function_Return iFail
        End_Function

    End_Object

    Procedure ActivateWorkspaceDialog
        Send Execute of (oWorkspaceOpen_Menuitem(ghoCommandBars))
    End_Procedure

    Procedure ActivateFileRadioButton
        Send Execute of (oFileRadioMenuItem(ghoCommandBars))
    End_Procedure

    Procedure ActivateCompare
        Send Execute of (oCompare_MenuItem(ghoCommandBars))
    End_Procedure

    Procedure ActivateBrowseDialog
        Send Execute of (oOpenFolderMenuItem(ghoCommandBars))
    End_Procedure

    Procedure ActivateProcess
        Send KeyAction of (oExecute_btn(oRefactorView(client_id(phoMainPanel(ghoApplication)))))
    End_Procedure

    Procedure ActivateSave
        Send Execute of (oSave_ToolItem(ghoCommandBars))
    End_Procedure

    Procedure ActivateClearAll
        Send Execute of (oClear_MenuItem(ghoCommandBars))
    End_Procedure

    Procedure ActivateSourceExplorer
        Send Execute of (oCodeExplorer_ToolbarButton(ghoCommandBars))
    End_Procedure

    Procedure ActivateSettings
        Send Execute of (oSettings_Toolbarbutton(ghoCommandBars))
    End_Procedure

    Procedure ActivateEditorSettings
        Send Execute of (oScintillaEditorSettings_Mentuitem(ghoCommandBars))
    End_Procedure

    Procedure ActivateUndoRefactoringDialog
        Send Execute of (oUndoRefactoring_MenuItem(ghoCommandBars))
    End_Procedure

    Procedure Switch_Prior_View
        Send Switch_Prior_View of (ClientAreaObject (ghoCommandBars))
    End_Procedure

    Procedure Switch_Next_View
        Send Switch_Next_View of (ClientAreaObject (ghoCommandBars))
    End_Procedure

    Procedure ToggleActionButton
        Integer iActiveView
        Handle  hoView
        Get piActiveView of ghoApplication to iActiveView
        If (iActiveView = CI_CleanupSource) Begin
            Get phoActiveView of ghoApplication to hoView
            Send ToggleActionButton of hoView
        End
    End_Procedure
    
//    Cant't have this as it collides with the DD_Debug dialog...
//    On_Key Key_Ctrl+Key_D  Send ActivateEditorSettings
    On_Key Key_Alt+Key_D   Send ActivateEditorSettings
    On_Key Key_Ctrl+Key_E  Send ActivateSourceExplorer
    On_Key Key_Alt+Key_E   Send ActivateSourceExplorer
    On_Key Key_Ctrl+Key_F  Send ActivateFileRadioButton
    On_Key Key_Alt+Key_F   Send ActivateFileRadioButton
    On_Key Key_Alt+Key_G   Send ToggleActionButton
    On_Key Key_Ctrl+Key_G  Send ToggleActionButton
    On_Key Key_Alt+Key_L   Send ShowLogFile of ghoApplication
    On_Key Key_Ctrl+Key_M  Send ActivateCompare
    On_Key Key_Alt+Key_M   Send ActivateCompare
    On_Key Key_Ctrl+Key_O  Send ActivateBrowseDialog
    On_Key Key_Alt+Key_O   Send ActivateBrowseDialog
    On_Key Key_Ctrl+Key_F5 Send ActivateProcess
    On_Key Key_Ctrl+Key_S  Send ActivateSave
    On_Key Key_Alt+Key_S   Send ActivateSave
    On_Key Key_Ctrl+Key_T  Send ActivateSettings
    On_Key Key_Alt+Key_T   Send ActivateSettings
    On_Key Key_Alt+Key_U   Send ActivateUndoRefactoringDialog
    On_Key Key_Ctrl+Key_W  Send ActivateWorkspaceDialog
    On_Key Key_Alt+Key_W   Send ActivateWorkspaceDialog
    On_Key Key_Alt+Key_X   Send Exit_Application
    On_Key Key_F2          Send ActivateSave
    On_Key Key_Ctrl+Key_F4 Send ActivateBrowseDialog

    // On_Key constant for Ctrl+Shift+Tab
    #IFNDEF C_CtrlShiftTab
        Define C_CtrlShiftTab for 7170
    #ENDIF

    Procedure End_Construct_Object
        Forward Send End_Construct_Object
        Set Icon to "DFRefactor.ico"
    End_Procedure

    On_Key C_CtrlShiftTab   Send Switch_Prior_View
    On_Key Key_Ctrl+Key_Tab Send Switch_Next_View
End_Object

Procedure OnStartup
    String sSWSFile
    
    Get psSWSFile of ghoApplication to sSWSFile
    If (sSWSFile <> "") Begin
        Send DisplayWorkspaceItem of (oWorkspaceSelector_Menuitem(ghoCommandBars)) sSWSFile
    End

    Send Activate_oRefactorView of (ClientAreaObject(ghoCommandBars)) 
    // This is weird. If this program is started from the TestBench,
    // the icon in Windows task bar is not showing. And the following line doesn't help either.
    Set Icon of (phoMainPanel(ghoApplication)) to "DFRefactor.ico"
    
    If (pbBatchMode(ghoRefactorEngine) = True) Begin
        Send RefactoreCode of (phoRefactorView(ghoApplication))
    End
End_Procedure
Send OnStartup

//  - If you get compile error: "Can't include resource ..\HELP\ABOUT.RTF",
//    you need to create a "About.rtf" file in the Help folder.
//    Note that it can be empty, but it needs to exist for the About dialog.
//    Or you can remark line 1302 in DfAbout.pkg = "Define ShouldEmbeddAboutHelpFile for 0" 
//
// -  If you get compile Error 4295: "xxx Can't include resource FILELISTBACKUPFILE.CFG",
//    you will need to manually make a copy of the Filelist.cfg in the Data folder -> "FilelistBackupFile.cfg"
Start_UI