PluginUpdateCore/build.gradle at main · NighterDevelopment/PluginUpdateCore · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
plugins {
    id 'java-library'
    id 'maven-publish'
}

group = 'io.github.pluginupdatecore'
version = '1.0.4'

repositories {
    mavenCentral()
    maven { name = "papermc-repo"; url = "https://repo.papermc.io/repository/maven-public/" }
}

dependencies {
    // Paper API - compileOnly because servers provide this
    compileOnly 'io.papermc.paper:paper-api:1.21.4-R0.1-SNAPSHOT'

    // Lombok for cleaner code
    compileOnly 'org.projectlombok:lombok:1.18.42'
    annotationProcessor 'org.projectlombok:lombok:1.18.42'
}

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
    withJavadocJar()
    withSourcesJar()
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
    options.release.set(21)
}

javadoc {
    options.encoding = 'UTF-8'
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId = 'io.github'
            artifactId = 'pluginupdatecore'
            version = project.version
            from components.java

            pom {
                name = 'PluginUpdateCore'
                description = 'A simple and efficient plugin update checker for Minecraft plugins.'
                url = 'https://github.com/NighterDevelopment/PluginUpdateCore'

                licenses {
                    license {
                        name = 'MIT License'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        id = 'nighter'
                        name = 'Nighter'
                        email = 'notnighter@gmail.com'
                    }
                }

                scm {
                    connection = 'scm:git:git://github.com/NighterDevelopment/PluginUpdateCore.git'
                    developerConnection = 'scm:git:ssh://github.com/NighterDevelopment/PluginUpdateCore.git'
                    url = 'https://github.com/NighterDevelopment/PluginUpdateCore'
                }
            }
        }
    }

    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://maven.pkg.github.com/NighterDevelopment/PluginUpdateCore")
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("GITHUB_ACTOR")
                password = project.findProperty("gpr.key") ?: System.getenv("GITHUB_TOKEN")
            }
        }
    }
}