Create-Pyro/build.gradle at master · CodedKyoko/Create-Pyro · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
plugins {
    id 'dev.architectury.loom' version "${loom_version}"
    id 'io.github.juuxel.loom-vineflower' version "${vineflower_version}"
    id 'io.github.p03w.machete' version '2.0.1'
    id 'maven-publish'
}

sourceCompatibility = targetCompatibility = JavaVersion.VERSION_17

group = project.maven_group
archivesBaseName = project.archives_base_name
String buildNumber = System.getenv("GITHUB_RUN_NUMBER")
version = "${mod_version}${ buildNumber != null ? "-${buildNumber}" : "" }+mc${minecraft_version}"

def generatedResources = file("src/generated/resources")

sourceSets.main.resources {
    srcDir(generatedResources)
    exclude ".cache/"
}

loom {
    silentMojangMappingsLicense()

    forge {
        mixinConfig "createpyro.mixins.json"
    }

    runs {
        data {
            data()
            programArgs '--mod', 'createpyro'
            programArg '--all'
            programArgs '--output', file('src/generated/resources/').absolutePath
            programArgs '--existing', file('src/main/resources/').absolutePath
        }
    }
}

repositories {
    mavenCentral()
    mavenLocal()
    maven { url 'https://maven.parchmentmc.org' }
    maven { url 'https://maven.quiltmc.org/repository/release' }
    maven { url 'https://maven.blamejared.com/' }

    maven {
        url 'https://maven.tterrag.com/'
        content {
            includeGroup 'com.jozufozu.flywheel'
            includeGroup 'com.tterrag.registrate'
            includeGroup 'com.simibubi.create'
        }
    }
    maven {
        url 'https://api.modrinth.com/maven'
        content { includeGroup 'maven.modrinth' }
    }
    maven {
        url 'https://www.cursemaven.com'
        content { includeGroup "curse.maven" }
    }

}

configurations {
    jarJar

    modImplementation.extendsFrom jarJar
    include.extendsFrom jarJar
}

dependencies {
    minecraft "com.mojang:minecraft:${minecraft_version}"

    mappings(loom.layered {
        it.mappings("org.quiltmc:quilt-mappings:${minecraft_version}+build.${quilt_mappings}:intermediary-v2")
        it.parchment("org.parchmentmc.data:parchment-${minecraft_version}:${parchment_version}@zip")
        it.officialMojangMappings { nameSyntheticMembers = false }
    })

    forge "net.minecraftforge:forge:${minecraft_version}-${forge_version}"

    // Create and Co.
    modImplementation "com.tterrag.registrate:Registrate:${registrate_version}"
    modImplementation("com.simibubi.create:create-${minecraft_version}:${create_version}:slim") { transitive = false }
    modImplementation "com.jozufozu.flywheel:flywheel-forge-${minecraft_version}:${flywheel_version}"

    // JEI
    modCompileOnly "mezz.jei:jei-${minecraft_version}-common-api:${jei_version}"
    modCompileOnly "mezz.jei:jei-${minecraft_version}-forge-api:${jei_version}"
    modLocalRuntime("mezz.jei:jei-${minecraft_version}-forge:${jei_version}") { transitive = false }

}

processResources {
    def props = [
            version: mod_version,
            forge_version: forge_version.split("\\.")[0], // only specify major version of forge
            minecraft_version: minecraft_version,
            create_version: create_version.split("-")[0] // cut off build number
    ]
    inputs.properties props

    filesMatching("META-INF/mods.toml") {
        expand props
    }
}

// disable machete locally for faster builds
machete { enabled = buildNumber != null }

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
    it.options.release.set 17
}

java { withSourcesJar() }

remapJar {
    archiveClassifier = 'dev'
}